243196_zh-CN

liliconcom

如何获得pass_fail列

我想要一个pass_fail列，并且 @txnelson 使它成为脚本。

但是，t 如果许多列中的任何一个在中间都没有规范，那么他的脚本将不起作用。 

我该如何解决？

Names Default To Here( 1 );
dtOrig = current data table();

colNamesList = dtOrig << get column names( continuous, string );

// Create a work table of just the continuous columns
dt = dtOrig << subset( columns( colNamesList ), selected rows( 0 ) );

// Loop across all of the columns and apply a Range Check to eliminate
// all data outside of the upper and lower spec limits
For( theCol = 1, theCol <= N Items( colNamesList ), theCol++,
 specs = Column( dt, colNamesList[theCol] ) << get property( "spec limits" );
 Eval(
  Substitute(
    Expr(
     Column( dt, colNamesList[theCol] ) << set property(
      "Range Check",
      (LELE( __LSL__, __USL__ ))
     )
    ),
   Expr( __LSL__ ), specs["LSL"],
   Expr( __USL__ ), specs["USL"]
  )
 );
 
 // Now convert the column to numeric 
 Column( dt, colNamesList[theCol] ) << data type( character );
  
 // Now find all cells where values were eliminated
 dt << select where( As Column( dt, colNamesList[theCol] ) == "" );
 
 // If non passing rows were found, process the column to change the passing rows to
 // a blank, and non passing to the name of the column
 If( N Rows( dt << get selected rows ) > 0,
  // Now set all eliminated cells to have the value of the name of the column
  Column( dt, colNamesList[theCol] )[dt << get selected rows] = Column( dt, colNamesList[theCol] ) <<
  get name;
  // Invert the row selection, to select all rows where values passed and set them to a blank
  dt << invert row selection;
  Column( dt, colNamesList[theCol] )[dt << get selected rows] = "";
 , // else set all 
  Column( dt, colNamesList[theCol] )[Index( 1, N Rows( dt ) )] = ""
 );
);

// Now create a new column to hold the information on either that the row Passed or 
// which columns failed
dt << New Column( "Pass_Fail", Character );

// Loop across all rows and set the values for the new column
For( theRow = 1, theRow <= N Rows( dt ), theRow++,
 If( Trim( Concat Items( dt[theRow, 0, ""] ) ) == "",
  :Pass_Fail[theRow] = "Pass"
 ,
  thePass_Fail = Concat Items( dt[theRow, 0], "," );
  For( i = Length( thePass_Fail ), i >= 2, i--,
   If( Substr( thePass_Fail, i, 1 ) == ",",
    If( Substr( thePass_Fail, i - 1, 1 ) == ",",
     thePass_Fail = Substr( thePass_Fail, 1, i - 1 ) || Substr( thePass_Fail, i + 1 )
    )
   )
  );
  If( Right( thePass_Fail, 1) == ",", thePass_Fail = Left( thePass_Fail, length( thePass_Fail ) - 1 ) );
  :Pass_Fail[theRow] = thePass_Fail;
 )
);

// Only the new column is what is needed, so delete all other columns
dt << delete columns( eval(colNamesList) );

// Add the new column to the original data table
dtOrig << Update(
 With( dt )
);

// Delete the no longer needed work table
close(dt, nosave );

 

 

回复：如何获取pass_fail列

TXnelson编写了非常出色的代码！

 

但是，也许您正在寻找一种简单的解决方案，例如：

If( :Data >= 42,"Too High",If( :Data < 7,"Too Low","Just Right"))

这只是一个嵌套的If语句，如果数据值为42或更高，则该公式返回“ Too High”，然后，如果数据小于7，则返回“ Too Low”，如果其值既不高又不太低，则公式返回“正好”

 

您可以将公式粘贴到公式编辑器中，然后替换为正确的列名称，值和消息。 （右键单击列名，单击“公式”，然后将上述JSL移到对话框中）

 

干杯，

乙

回复：如何获取pass_fail列

我喜欢简单，喜欢我！

 

所以我简化了它（不需要嵌套）：

 

If( :Data >= 42, "Too High", :Data < 7, "Too Low", "Just Right")

回复：如何获取pass_fail列

我要感谢 @Byron_JMP 为了回应。  我原本打算回应此讨论，但在此之前，它转移到了较旧的页面，因此失去了记忆。  拜伦的回应使讨论重新回到了我的NameSpace。 
我相信您要解决此问题所要做的就是验证给定的列具有与之相关的规格限制。  并且，如果未找到规格限制，则不要处理该列。  下面是一个有点神秘的建议更改，它可能会做您想要的。  问题的基础是使用If（）函数仅在找到规格限制时才处理代码。这是您当前规格=代码行的替代

clear symbols(specs);
specs = Column( dt, colNamesList[theCol] ) << get property( "spec limits" );
If(isEmpty(specs)==0,
 <ALL of="" the="" code="" to="" the="" end="" of="" the="" for="" loop=""></ALL>

 

回复：如何获取pass_fail列谢谢你的帮助！
这段代码效果很好！
谢谢:)