242228_it-IT

liliconcom

iterare un elenco di tabelle di dati aperte e concatenarlo in una tabella

Sto cercando di concatenare un gruppo di file di registro in un unico file e sto utilizzando la versione 13...JMP 14 è molto più semplice... Dato che altri utilizzeranno jmp 13 per un po' di tempo, ho bisogno di creare uno script generico.

Lo script che ho in questo momento può generare una serie di tabelle di dati aperti. Funziona bene.Posso scorrere e acquisire un elenco di openDT..

Ma quando provo a concatenare non ho avuto successo. Non ho nemmeno bisogno di aprire le tabelle, basta concatenarle in un unico file.

 

Qualcuno là fuori può aiutarmi a capire questo problema?

_______________________________________________________

 

Ho eseguito la funzione di concatenazione su uno dei log aperti e ho generato questo:

 

Data Table( "test_data_1.log" ) << Concatenate(
 Data Table( "test_data_2.log" ),
 Data Table( "test_data_3.log" ),
 Output Table( "RESULTS" ),
 Create source column
);

 

___________________________________________________

names = {"/C:/1test/test_data_1.log", "/C:/1test/test_data_2.log", "/C:/1test/test_data_3.log"};
openDTs = {DataTable("test_data_3.log"), DataTable("test_data_2.log"), DataTable("test_data_1.log")};

Nome non risolto: risultati nell'accesso o nella valutazione di 'Risultati', Risultati/*###*/

Nello script seguente, errore contrassegnato da /*###*/

dirpath = Munger( Pick Directory( "JMP 13.xx locate the LOG FILES: " ), 1, "/", "" );
Set Current Directory( dirpath );
names = Files In Directory( dirpath, recursive( 1 ) );
For( i = 1, i <= N Items( names ), i++,
 dt1 = Open(
  names[i] = Convert File Path( dirpath ) || names[i],
  columns(
   Column( "STARTDATETIME", Numeric, "Continuous", Format( "y/m/d h:m:s", 26, 3 ), Input Format( "y/m/d h:m:s", 3 ) ),
   Column( "FIVER", Numeric, "Continuous", Format( "Best", 12 ) ),
   Column( "CLASS", Character, "Nominal" ),
   Column( "BLANK", Character( 1 ), "Nominal" ),
   Column( "TYPE", Character, "Nominal" ),
   Column( "CSTARGET", Character, "Nominal" ),
   Column( "CSACTION", Character, "Nominal" ),
   Column( "NUMCODE", Numeric, "Continuous", Format( "Best", 12 ) ),
   Column( "DEVICE", Character, "Nominal" ),
   Column( "DATA", Character, "Nominal" ),
   Column( "ENDDATE", Numeric, "Continuous", Format( "y/m/d h:m:s", 29, 6 ), Input Format( "y/m/d h:m:s", 6 ) ),
   Column( "JUNK1", Numeric, "Continuous", Format( "y/m/d h:m:s", 29, 6 ), Input Format( "y/m/d h:m:s", 6 ) ),
   Column( "JUNK2", Numeric, "Continuous", Format( "Best", 12 ) )
  ),
  Import Settings(
   End Of Line( CRLF, CR, LF ),
   End Of Field( Other( "0x7c" ), CSV( 0 ) ),
   Strip Quotes( 1 ),
   Use Apostrophe as Quotation Mark( 0 ),
   Use Regional Settings( 0 ),
   Scan Whole File( 1 ),
   Treat empty columns as numeric( 0 ),
   CompressNumericColumns( 0 ),
   CompressCharacterColumns( 0 ),
   CompressAllowListCheck( 0 ),
   Labels( 0 ),
   Column Names Start( 1 ),
   Data Starts( 1 ),
   Lines To Read( "All" ),
   Year Rule( "20xx" )
  )
 );
 Current Data Table( dt1 );
 dt1 << delete columns( "CLASS", "FIVER", "BLANK", "JUNK1", "JUNK2" );
 dt1 << Select Where(
  Contains( As Column( dt1, "TYPE" ), "Execute" ) | Contains( As Column( dt1, "TYPE" ), "++" ) | Contains(
   As Column( dt1, "TYPE" ),
   "SetState"
  ) | Contains( As Column( dt1, "TYPE" ), "SAM" ) | Contains( As Column( dt1, "TYPE" ), "DAC" )
 );
 dt1 << Delete Rows;
);
Show( names );
openDTs = {};
For( i = 1, i <= N Table(), i++,
 Insert Into( openDTs, Data Table( i ) )
);
Show( openDTs );
dt = New Table( "Results" );
For( k = 1, k <= N Items( names ), k++,
 Current Data Table( Results/*###*/ );
 dt << concatenate( Data Table( names[k] ), Output Table( "Results" ), Create Source column );
);

Ri: ripetere un elenco di tabelle di dati aperti e concatenarlo in una tabella

Jim - Grazie... ho fatto una revisione.... senza analizzare i dati in colonne apro i file, quindi aggiungo una colonna di origine. Quindi concatenare. Quindi prendi il file concatenato e analizzalo. La sua progressione più rapida e logica. aggiunto quanto segue:

// create the variables to set the column name and
// define the column value
cName = "SOURCE";
fName = dt1 << get name;
dt1 << New Column( cName, Character, Nominal, Set each value( fName ) );

Then iterate the open tables:
// define a list of open data tables.
openDTs = List();
For( i = 1, i <= N Table(), i++,
 Insert Into( openDTs, Data Table( i ) )
);
// Loop through the data tables again and concatenate
For( k = 2, k <= N Items( openDTs ), k++,
 Current Data Table();
 dtUpdated = Current Data Table() << Concatenate( openDTs[k] );
 Close( openDTs[k], nosave );
);

Funziona bene adesso.

Ri: ripetere un elenco di tabelle di dati aperti e concatenarlo in una tabella

La funzione Current Data Table() deve essere modificata in

Current Data Table( dt );

o a

Current Data Table( data table( "Results" ) );

Tuttavia, in genere eseguo la concatenazione man mano che ciascun file viene letto.A me sembra più pulito

Names default to here(1);
dirpath = Munger( Pick Directory( "JMP 13.xx locate the LOG FILES: " ), 1, "/", "" );
Set Current Directory( dirpath );
names = Files In Directory( dirpath, recursive( 1 ) );

dt = New Table( "Results" );

For( i = 1, i <= N Items( names ), i++,
 dt1 = Open(
  names[i] = Convert File Path( dirpath ) || names[i],
  columns(
   Column( "STARTDATETIME", Numeric, "Continuous", Format( "y/m/d h:m:s", 26, 3 ), Input Format( "y/m/d h:m:s", 3 ) ),
   Column( "FIVER", Numeric, "Continuous", Format( "Best", 12 ) ),
   Column( "CLASS", Character, "Nominal" ),
   Column( "BLANK", Character( 1 ), "Nominal" ),
   Column( "TYPE", Character, "Nominal" ),
   Column( "CSTARGET", Character, "Nominal" ),
   Column( "CSACTION", Character, "Nominal" ),
   Column( "NUMCODE", Numeric, "Continuous", Format( "Best", 12 ) ),
   Column( "DEVICE", Character, "Nominal" ),
   Column( "DATA", Character, "Nominal" ),
   Column( "ENDDATE", Numeric, "Continuous", Format( "y/m/d h:m:s", 29, 6 ), Input Format( "y/m/d h:m:s", 6 ) ),
   Column( "JUNK1", Numeric, "Continuous", Format( "y/m/d h:m:s", 29, 6 ), Input Format( "y/m/d h:m:s", 6 ) ),
   Column( "JUNK2", Numeric, "Continuous", Format( "Best", 12 ) )
  ),
  Import Settings(
   End Of Line( CRLF, CR, LF ),
   End Of Field( Other( "0x7c" ), CSV( 0 ) ),
   Strip Quotes( 1 ),
   Use Apostrophe as Quotation Mark( 0 ),
   Use Regional Settings( 0 ),
   Scan Whole File( 1 ),
   Treat empty columns as numeric( 0 ),
   CompressNumericColumns( 0 ),
   CompressCharacterColumns( 0 ),
   CompressAllowListCheck( 0 ),
   Labels( 0 ),
   Column Names Start( 1 ),
   Data Starts( 1 ),
   Lines To Read( "All" ),
   Year Rule( "20xx" )
  )
 );
 Current Data Table( dt1 );
 dt1 << delete columns( "CLASS", "FIVER", "BLANK", "JUNK1", "JUNK2" );
 dt1 << Select Where(
  Contains( As Column( dt1, "TYPE" ), "Execute" ) | Contains( As Column( dt1, "TYPE" ), "++" ) | Contains(
   As Column( dt1, "TYPE" ),
   "SetState"
  ) | Contains( As Column( dt1, "TYPE" ), "SAM" ) | Contains( As Column( dt1, "TYPE" ), "DAC" )
 );
 dt1 << Delete Rows;
 dt1 << rerun formulas; // make sure all dt1 operations are complete
 
 // Concatenate to the Results data table
 dt << concatenate( dt1, Append to first table( 1 ), Create Source Column );
 
 // To keep the work environment clean, I normally delete the latest input data table
 close( dt1, nosave );
);