240709_zh-TW

liliconcom

通過 X 圖或相關圖擬合多個參數的 Y

 

我想對 2 組數據的多個參數進行 Y by X 擬合，如下所示。 如果我只想執行 1 個參數，那就非常簡單了。 我只需要將溫度從行拆分到列，然後手動選擇 param1 temp1 與 param1 temp2。 但如果我有 100 個參數，似乎不太實用。 有沒有其他系統或簡單的方法來實現這一目標？

 

溫度	參數1	參數2	參數3	參數
溫度1	xx	xx	xx	xx
溫度1	xx	xx	xx	xx
溫度1	xx	xx	xx	xx
溫度1	xx	xx	xx	xx
溫度2	xx	xx	xx	xx
溫度2	xx	xx	xx	xx
溫度2	xx	xx	xx	xx
溫度2	xx	xx	xx	xx

 

拆分錶後是這樣的。

 

回复：通過 X 圖或相關圖擬合多個參數的 Y謝謝尼爾森。 我認為這可能是我能得到的封閉解決方案。回复：通過 X 圖或相關圖擬合多個參數的 Y

我不知道有什麼直接的方法可以做到你想要的，但是下面的腳本可以做到這一點。它使用 JMP 樣本數據表中的半導體能力數據表。我認為代碼足夠簡單，您可以使用它。

Names Default To Here( 1 );
// open the semiconductor data table and add a Temp column to it
// to mimic the data table you are using
dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );
// Add a Temp Column
dt << New Column( "Temp", nominal, formula( If( Row() < N Rows( dt ) / 2, -26, -30 ) ) );

// Create a list of all of the parameters
colList = dt << get column names( continuous, string );

// Turn on the Show Limits for all of the columns
For( i = 1, i <= N Items( colList ), i++,
 spec = Column( dt, colList[i] ) << get property( "spec limits" );
 insert into(spec,expr(show limits(1)));
 column( dt, colList[i] ) << set property("spec limits", eval(spec));
);

// Create the split data table
dtSplit = dt << Split(
 Split By( :Temp ),
 Split( Eval( colList ) ),
 Remaining Columns( Drop All ),
 Sort by Column Property
);

// Create an output window to place the graphs into
nw = New Window( "Outputs", lub = Lineup Box( N Col( 4 ) ) );

// Since the columns desired are side by side, loop across
// the columns and create the graphs and add them to the
// output window
For( i = 1, i <= N Cols( dtSplit ), i = i + 2,
 lub << append(
  Graph Builder(
   Size( 350, 350 ),
   Show Control Panel( 0 ),
   Variables( X( As Column( dtSplit, i ) ), Y( As Column( dtSplit, i + 1 ) ) ),
   Elements( Points( X, Y, Legend( 5 ) ) )
  )
 )
);

回复：通過 X 圖或相關圖擬合多個參數的 Y

感謝您的回复。 您的任何一個選項都符合我的要求。 也許我的解釋一開始就不夠清楚。

 

多元確實可以同時處理 1 與 N 參數。 但如果你想做數百個參數，這實際上是不可行的。 而且我也不需要 1 vs N 參數相關性。 我只需要 1 對 1 的參數相關性。 您的第二個選擇實際上是建議按 Temp 進行 Param1 與 Param2 組，這也不是我的想法。

 

我真正想要的是..

Chart1：Y 軸將是 temp1 param1，X 軸將是 temp2 param1。

圖 2：Y 軸為 temp1 param2，X 軸為 temp2 param2。

等等......100 數百個參數

回复：通過 X 圖或相關圖擬合多個參數的 Y希望我正確理解了你的任務。

在圖形、散點圖矩陣下，您可以將所有感興趣的參數 )Param1、Param2、Param3,,,) 輸入到 Y 角色和感興趣的分組依據類別（在您的情況下為 TEMP）。

希望這可以幫助。

- 菲利普回复：通過 X 圖或相關圖擬合多個參數的 Y

我將您的請求解釋為在製作散點圖時您有許多數據列可用於 X 和 Y 角色。 多元平台自動生成此類散點圖的矩陣。 輸入 Y 角色中的所有變量，您將獲得所有可能的散點圖，一次兩個變量。

 

然而，另一種解釋是您想要相同的散點圖，但按“Temp”分割數據。 如果是這樣，則當您通過“Fit Y by X”對話框啟動雙變量平台時，將 Temp 置於“按”角色中。

 

最後，如果需要在 X 或 Y 角色中以交互方式探索具有不同數據列的散點圖，則可以使用列切換器功能。

 

希望這些建議之一能夠對您有所幫助或迅速澄清您想要做什麼。