240709_de-DE

liliconcom

Passen Sie das Y-x-Diagramm oder das Korrelationsdiagramm für mehrere Parameter an

 

Ich möchte ein Fit-Y-by-X-Diagramm für mehrere Parameter für zwei Datengruppen wie unten erstellen. Wenn ich nur 1 Parameter ausführen möchte, ist das ziemlich einfach. Ich muss nur die Temperatur von Zeile zu Spalte aufteilen und manuell param1 temp1 vs. param1 temp2 auswählen. Aber wenn ich 100 Parameter habe, scheint es nicht so praktisch zu sein. Gibt es eine andere systematische oder einfache Möglichkeit, dies zu erreichen?

 

Temp	param1	param2	param3	paramx
temp1	xx	xx	xx	xx
temp1	xx	xx	xx	xx
temp1	xx	xx	xx	xx
temp1	xx	xx	xx	xx
temp2	xx	xx	xx	xx
temp2	xx	xx	xx	xx
temp2	xx	xx	xx	xx
temp2	xx	xx	xx	xx

 

Nach der Aufteilung der Tabelle etwa so.

 

Betreff: Y-x-Diagramm oder Korrelationsdiagramm für mehrere Parameter anpassenDanke Nelson. Ich denke, es könnte die geschlossene Lösung sein, die ich bekommen kann.Betreff: Y-x-Diagramm oder Korrelationsdiagramm für mehrere Parameter anpassen

Mir ist keine direkte Möglichkeit bekannt, das zu tun, was Sie wollen, aber das folgende Skript wird es tun.Es wird die Datentabelle „Halbleiterfähigkeit“ aus den JMP-Beispieldatentabellen verwendet.Ich denke, der Code ist einfach genug, um ihn bei Ihrer Verwendung zu verarbeiten.

Names Default To Here( 1 );
// open the semiconductor data table and add a Temp column to it
// to mimic the data table you are using
dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );
// Add a Temp Column
dt << New Column( "Temp", nominal, formula( If( Row() < N Rows( dt ) / 2, -26, -30 ) ) );

// Create a list of all of the parameters
colList = dt << get column names( continuous, string );

// Turn on the Show Limits for all of the columns
For( i = 1, i <= N Items( colList ), i++,
 spec = Column( dt, colList[i] ) << get property( "spec limits" );
 insert into(spec,expr(show limits(1)));
 column( dt, colList[i] ) << set property("spec limits", eval(spec));
);

// Create the split data table
dtSplit = dt << Split(
 Split By( :Temp ),
 Split( Eval( colList ) ),
 Remaining Columns( Drop All ),
 Sort by Column Property
);

// Create an output window to place the graphs into
nw = New Window( "Outputs", lub = Lineup Box( N Col( 4 ) ) );

// Since the columns desired are side by side, loop across
// the columns and create the graphs and add them to the
// output window
For( i = 1, i <= N Cols( dtSplit ), i = i + 2,
 lub << append(
  Graph Builder(
   Size( 350, 350 ),
   Show Control Panel( 0 ),
   Variables( X( As Column( dtSplit, i ) ), Y( As Column( dtSplit, i + 1 ) ) ),
   Elements( Points( X, Y, Legend( 5 ) ) )
  )
 )
);

Betreff: Y-x-Diagramm oder Korrelationsdiagramm für mehrere Parameter anpassen

Danke für die Antwort. Eine Ihrer Optionen entsprach meinen Anforderungen. Vielleicht ist meine Erklärung von vornherein nicht klar genug.

 

Multivariat kann tatsächlich 1 vs. N Parameter gleichzeitig ausführen. Dies ist jedoch nicht praktikabel, wenn Sie Hunderte von Parametern ausführen möchten. Und ich brauche auch keine 1-gegen-N-Parameterkorrelation. Ich brauche nur eine 1:1-Parameterkorrelation. Ihre zweite Option besteht tatsächlich darin, eine Param1- vs. Param2-Gruppe nach Temp vorzuschlagen, was ebenfalls nicht meine Idee ist.

 

Was ich wirklich will ist ..

Diagramm1: Die Y-Achse ist temp1 param1 und die X-Achse ist temp2 param1.

Diagramm2: Die Y-Achse ist temp1 param2 und die X-Achse ist temp2 param2.

und so weiter.... für 100 Hunderte Parameter

Betreff: Y-x-Diagramm oder Korrelationsdiagramm für mehrere Parameter anpassenHoffentlich habe ich deine Aufgabe richtig verstanden.

Unter Diagramm, Streudiagrammmatrix können Sie alle interessierenden Parameter (Param1, Param2, Param3,,,) in die Y-Rolle und die interessierende Kategorie „Gruppieren nach“ eingeben, in Ihrem Fall TEMP.

Hoffe das hilft.

- PhilippBetreff: Y-x-Diagramm oder Korrelationsdiagramm für mehrere Parameter anpassen

Ich interpretiere Ihre Anfrage so, dass Sie viele Datenspalten haben, die sowohl in der X- als auch in der Y-Rolle verwendet werden müssen, wenn Sie ein Streudiagramm erstellen. Die Multivariate-Plattform erstellt automatisch eine Matrix solcher Streudiagramme. Geben Sie alle Variablen in der Y-Rolle ein und Sie erhalten alle möglichen Streudiagramme, jeweils zwei Variablen.

 

Eine andere Interpretation ist jedoch, dass Sie dasselbe Streudiagramm wünschen, die Daten jedoch nach „Temp“ aufteilen möchten. Wenn ja, dann geben Sie „Temp“ die Rolle „Nach“ an, wenn Sie die Bivariate-Plattform über das Dialogfeld „Y nach X anpassen“ starten.

 

Wenn schließlich das Streudiagramm interaktiv mit verschiedenen Datenspalten in der X- oder Y-Rolle untersucht werden muss, verwenden Sie die Funktion „Spaltenumschalter“.

 

Wir hoffen, dass einer dieser Vorschläge hilfreich ist oder Ihnen schnell Klarheit darüber verschafft, was Sie tun möchten.