240301_de-DE

liliconcom

Wie ersetze ich automatisch generierte Parameter in einem Bubble-Plot durch benutzerdefinierte Farbparameter?

Dt = Open ("$ SAMPLE_DATA \ World Demographics. Das JMP ");
Blenden Sie die erste Zeile aus und löschen Sie die ersten fünf Spalten mit "(1000)" im Spaltennamen.
Generieren Sie das Bubble-Plot mit dem folgenden Code.

dt = Current Data Table();
c11 = Quantile( 1, (:Crude Birth Rate << get values) ) * 1.01;
c12 = Quantile( 0, (:Crude Birth Rate << get values) ) * 0.99;
c21 = Quantile( 1, (:Crude Death Rate << get values) ) * 1.01;
c22 = Quantile( 0, (:Crude Death Rate << get values) ) * 0.99;
c31 = Quantile( 1, (:Population << get values) );
c32 = Quantile( 0, (:Population << get values) );
pa = {0.05, 0.275, 0.5, 0.725, 0.95};
xF = {};
For( c = 1, c <= 5, c++,
 na = Quantile( pa[c], (:Infant Mortality Rate << get values) );
 Insert Into( xF, na );
);


Bubble Plot(
 X( :Crude Birth Rate ),
 Y( :Crude Death Rate ),
 Sizes( :Population ),
 Coloring( :Infant Mortality Rate ),
 ID( :Territory ),
 Color Levels( xF ),
 Title Position( 0, 0 ),
 SendToReport(
  Dispatch( {}, "1", ScaleBox, {Format( "Best", 10 ), Min( c12 ), Max( c11 ), Inc( 5 ), Minor Ticks( 1 )} ),
  Dispatch( {}, "2", ScaleBox, {Format( "Best", 12 ), Min( c22 ), Max( c21 ), Inc( 5 ), Minor Ticks( 0 )} )
 )
);
Wait( 0 );

Wie ersetze ich automatisch generierte Parameter in einem Bubble-Plot durch benutzerdefinierte Farbparameter?
Der von der Software automatisch generierte Parameter-JSL-Code lautet

Color Levels([2.31 46.785 91.26 135.735 180.21])

Wie schreibe ich JSL, wenn ich stattdessen meine eigenen Parameter verwenden möchte?

Vielen Dank!

Betreff: Wie ersetze ich automatisch generierte Parameter durch benutzerdefinierte Farbparameter in einem Blasendiagramm?

Das Argument für Color Levels () muss eine Matrix sein - das Listenargument wird ignoriert.  Hier ist ein Beispiel, das funktioniert:

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/PopAgeGroup.jmp" );
cl = [100000 150000000 300000000 450000000 600000000];
obj = Bubble Plot(
 X( :Name( "Portion 0-19" ) ),
 Y( :Name( "Portion60+" ) ),
 Sizes( :Pop ),
 Coloring( :Pop ),
 ID( :Country ),
 Color Levels( cl )
);

Betreff: Wie ersetze ich automatisch generierte Parameter durch benutzerdefinierte Farbparameter in einem Blasendiagramm?

Danke, danschikore!
Jetzt liegt der Fokus auf der Umwandlung von xf in eine Matrixform. Ich habe gesucht und kann die Antwort immer noch nicht finden. Bitten Sie um Hilfe.

Ich habe versucht, Code so zu schreiben, aber es hat nicht funktioniert. Danke!

……<BR />Mat = Number Col Box("",xf) << get as matrix;<BR />……<BR />Color Levels( Mat ),

Betreff: Wie ersetze ich automatisch generierte Parameter durch benutzerdefinierte Farbparameter in einem Blasendiagramm?

Das JMP Scripting Guide hat einen guten Überblick über die Verwendung von Matrizen in JSL.  Wenn Sie bereits eine Liste haben, können Sie diese in eine Matrix konvertieren:

 

Create a column vector from a single list:

A = Matrix( {1, 2, 3} );
[1,2,3]

Sie können auch eine leere Matrix erstellen und diese durch Verketten aufbauen, ähnlich wie Sie die Liste verwendet haben:

 

cl = [];
cl = cl || 100000;
cl = cl || 150000000;
cl = cl || 300000000;
cl = cl || 450000000;
cl = cl || 600000000;

[100000 150000000 300000000 450000000 600000000]

Wenn Sie die Größe der Matrix im Voraus kennen, können Sie die vollständige Matrix erstellen und mithilfe von Indizes Werte zuweisen:

 

cl = J(1,5);
cl[1] = 100000;
cl[2] = 150000000;
cl[3] = 300000000;
cl[4] = 450000000;
cl[5] = 600000000;
Show(cl);

cl = [100000 150000000 300000000 450000000 600000000];

Ich hoffe, das hilft!