Nested Chart Drill Downs using Mousetrap()

tsl

I have a use case to build a chart which will have a drill-down capability.

The user will click on a point on the chart and, using the Mousetrap() function a script will run which will pop up a new window containing another chart with some more detailed drill down information.

I want to then support an additional level of drill down from this first pop-up window.

I will illustrate with a simple example using BigClass dataset in the attached script.

The notes in the script highlight the problem : with only one mouse-trap() function call, the first drill down works.

But if I add a second mouse-trap, specifically adding it to the graph that will result from the first drill-down, what instead happens is that the second drill-down action is applied to the first mouse click, which wasn't expected.

Not sure if it's possible to use MouseTrap() like this or not ?

 

 

d

 

DoubleDrill-Down.jsl

Craige_Hales

Cool idea! Move your code into a function and it works:

makesubset = Function( {_x},
	{TestWin}, // local variables
	dt << select where( :height == _x );
	TestWin = New Window( "Drill Down Window",
		dt << GraphBuilder( Size( 534, 448 ), Show Control Panel( 0 ),
			Where( Selected() ), Variables( X( :sex ), Y( :weight ) ),
			Elements( Points( X, Y, Legend( 4 ) ), Box Plot( X, Y, Legend( 5 ) ) )
		)
	);
	TestWin[FrameBox( 1 )] << add graphics script(
		Mousetrap(
			_x2 = Round( X, 0 );
			Show( _x2 );
		)
	);
);

dt = Open( "$sample_data/big class.jmp" );
dt << Graph Builder( Size( 527, 454 ), Show Control Panel( 0 ),
	Variables( X( :height ) ), Elements( Bar( X, Legend( 6 ) ) ),
	SendToReport( Dispatch( {}, "Graph Builder", FrameBox,
			{Add Graphics Script( 2, Description( "Script" ),
				Mousetrap(
					_x = Round( X, 0 );
					makesubset( _x );
				)
			), Grid Line Order( 1 ), Reference Line Order( 3 )}
		)
	)
);

It behaves the way you describe because the Mousetrap function isn't really executed like other functions. The <<addGraphicScript method has to scan for the MouseTrap(s) and ...something...

I suspect it keeps the last one. The scanning will not follow into the function call, and the function call may make your JSL easier to read and maintain.

@EvanMcCorkle Yes, it seems odd that it finds a mousetrap inside of a mousetrap.