ペアデータが1000セット以上あるデータを分析すると、A vs B、C vs Dなど、1000回以上選択できなかった…
ペアになっているすべてのデータを一度に比較できるように、それらを Excel の表にまとめるにはどうすればよいですか?
以下は、データに対して実行される簡単なスクリプトです。このスクリプトは、2 つのワークブックを 2 つの別個のテーブルとして JMP に読み込んだことを前提としています。次に、各データ テーブルの列の名前を決定し、テーブルを結合してから、Matched Pairs プラットフォームを実行します。Excel ワークブックから使用した 2 つの JMP テーブルを添付しました。
さらに、3000 列の一致する独自のサンプル データ テーブルを作成し、3000 列すべてで Matched Pairs プラットフォームを実行しましたが、エラーなく動作しました。
Names Default To Here( 1 );
// Create a pointer to the Pre data table and get
// a list of the columns in it
dt1 = Data Table( "sample data_Sheet1" );
colList1 = dt1 << get column names( continuous );
// Create a pointer to the Post data table and get
// a list of the columns in it
dt2 = Data Table( "sample data_Sheet2" );
colList2 = dt2 << get column names( continuous );
// Join the data tables together
dtJoined = dt1 << Join(
With( dt2 ),
By Matching Columns( :ID = :ID ),
Drop multiples( 0, 0 ),
Include Nonmatches( 0, 0 ),
Preserve main table order( 1 )
);
// create a new list in the column order required for the Matched Pairs platform
// which is pre1, post1, pre2, post2, etc.
finalList = {};
For( i = 1, i <= N Items( colList1 ), i++,
Insert Into( finalList, colList1[i] );
Insert Into( finalList, colList2[i] );
);
// Run the matched pairs
dtJoined << Matched Pairs(
Y( Eval( finalList ) ),
Separate Pairs( 1 ),
Reference Frame( 1 ),
Wilcoxon Signed Rank( 1 )
);
お返事ありがとうございます。
列 A に同じ ID を持つ 2 つのシートをそれぞれ含む添付の Excel ファイル。
Sheet1-Pre と Sheet2-Post の各 COMPOUND を一度に比較します。 各化合物には 243 個の生データが含まれます。
たとえば、Wilcoxon の符号付き順位検定 (対応のある t 検定に相当するノンパラメトリック) を使用して、Sheet1-Pre の COMPOUND1 を Sheet2-Post の COMPOUND1 と比較し、Sheet1-Pre の COMPOUND2 と Sheet2- の COMPOUND2 を比較します。投稿などをまとめて。
やあ@酒井、
小さなサンプルと、必要な比較の例を教えてください。ほとんどの場合、それほど難しくありません。
