238631_fr-FR

liliconcom

Par groupes dans la formule de colonne dans la boucle for

Salut,

 

Je parcours les colonnes pour créer de nouvelles colonnes de moyens, de développement standard et de CV pour chaque colonne. J'ai le script ci-dessous, qui fonctionne bien pour les statistiques globales des colonnes, mais lorsque j'essaie d'ajouter par groupes, comme je l'ai fait dans la colonne moyenne, la formule échoue.

 

Je me rends compte que je pourrais accomplir la même chose en utilisant un tableau récapitulatif mis à jour dans le tableau principal.

 

Merci!

 

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp");

New Column("Old",
   Character,
   Formula(If(:age>=14,"Old","Young"))
   );

colnames = dt << get column names( numeric,string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
   Expr(
    New Column( Char( colnames[i] ) || " mean",
    Numeric,
    Formula(
     Col Mean(Column(__colname__),:old)
    ) 
    );
    New Column( Char( colnames[i] ) || " STD DEV",
    Numeric,
    Formula(
     Col Std Dev(Column(__colname__))
    ) 
    );
    New Column( Char( colnames[i] ) || " CV%",
    Numeric,
    Format( "Percent", 2 ),
    Formula(
     Col Std Dev(Column(__colname__))/
     Col Mean(Column(__colname__))
    ) 
    );
   ),
  Expr(__colname__),colnames[i]
  )
 )
);

Re : Par groupes dans la formule de colonne dans la boucle forMerci Jim, fonctionne parfaitement !Re : Par groupes dans la formule de colonne dans la boucle for

JMP semble avoir un problème avec l'utilisation uniquement de la fonction Column().Cependant, la fonction As Column() corrige le problème.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean( as Column( __colname__ ), :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev( as Column( __colname__ ) ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( as Column( __colname__ ) ) / Col Mean( as Column( __colname__ ) ) )
     );
    ),
   Expr( __colname__ ), colnames[i]
  )
 )
);

Puisque vous utilisez la fonction Substitute(), vous pouvez également supprimer les fonctions As Column() ou Column() et remplacer le __colname__ par la référence de colonne réelle de :theactualcolumnname. Voir ci-dessous

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean(  __colname__ , :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev(  __colname__  ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( __colname__  ) / Col Mean(  __colname__  ) )
     );
    ),
   Expr( __colname__ ), Parse( ":" || colnames[i] )
  )
 )
);