238631_de-DE

liliconcom

Nach Gruppen in der Spaltenformel in der for-Schleife

Hallo,

 

Ich durchlaufe die Spalten, um für jede Spalte neue Spalten mit Mittelwerten, Std.-Abw. und CV zu erstellen. Ich habe das folgende Skript, das für globale Spaltenstatistiken gut funktioniert, aber wenn ich versuche, nach Gruppen hinzuzufügen, wie ich es in der mittleren Spalte getan habe, schlägt die Formel fehl.

 

Mir ist klar, dass ich dasselbe erreichen könnte, wenn ich eine Übersichtstabelle verwenden würde, die wieder in die Haupttabelle aktualisiert wird.

 

Danke!

 

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp");

New Column("Old",
   Character,
   Formula(If(:age>=14,"Old","Young"))
   );

colnames = dt << get column names( numeric,string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
   Expr(
    New Column( Char( colnames[i] ) || " mean",
    Numeric,
    Formula(
     Col Mean(Column(__colname__),:old)
    ) 
    );
    New Column( Char( colnames[i] ) || " STD DEV",
    Numeric,
    Formula(
     Col Std Dev(Column(__colname__))
    ) 
    );
    New Column( Char( colnames[i] ) || " CV%",
    Numeric,
    Format( "Percent", 2 ),
    Formula(
     Col Std Dev(Column(__colname__))/
     Col Mean(Column(__colname__))
    ) 
    );
   ),
  Expr(__colname__),colnames[i]
  )
 )
);

Betreff: Nach Gruppen in der Spaltenformel in der for-SchleifeDanke Jim, funktioniert perfekt!Betreff: Nach Gruppen in der Spaltenformel in der for-Schleife

JMP scheint ein Problem damit zu haben, nur die Column()-Funktion zu verwenden.Die Funktion „As Column()“ behebt das Problem jedoch.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean( as Column( __colname__ ), :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev( as Column( __colname__ ) ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( as Column( __colname__ ) ) / Col Mean( as Column( __colname__ ) ) )
     );
    ),
   Expr( __colname__ ), colnames[i]
  )
 )
);

Da Sie die Funktion Substitute() verwenden, können Sie auch die Funktionen As Column() oder Column() entfernen und __colname__ durch die tatsächliche Spaltenreferenz von :theactualcolumnname ersetzen. Siehe unten

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean(  __colname__ , :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev(  __colname__  ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( __colname__  ) / Col Mean(  __colname__  ) )
     );
    ),
   Expr( __colname__ ), Parse( ":" || colnames[i] )
  )
 )
);