238631_it-IT

liliconcom

Per gruppi nella formula di colonna nel ciclo for

CIAO,

 

Sto scorrendo le colonne per creare nuove colonne di medie, sviluppo std e CV per ciascuna colonna. Ho lo script seguente, che funziona bene per le statistiche globali delle colonne, ma quando provo ad aggiungere per gruppi, come ho fatto nella colonna media, la formula fallisce.

 

Mi rendo conto che potrei ottenere lo stesso risultato utilizzando una tabella di riepilogo aggiornata nella tabella principale.

 

Grazie!

 

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp");

New Column("Old",
   Character,
   Formula(If(:age>=14,"Old","Young"))
   );

colnames = dt << get column names( numeric,string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
   Expr(
    New Column( Char( colnames[i] ) || " mean",
    Numeric,
    Formula(
     Col Mean(Column(__colname__),:old)
    ) 
    );
    New Column( Char( colnames[i] ) || " STD DEV",
    Numeric,
    Formula(
     Col Std Dev(Column(__colname__))
    ) 
    );
    New Column( Char( colnames[i] ) || " CV%",
    Numeric,
    Format( "Percent", 2 ),
    Formula(
     Col Std Dev(Column(__colname__))/
     Col Mean(Column(__colname__))
    ) 
    );
   ),
  Expr(__colname__),colnames[i]
  )
 )
);

Ri: Per gruppi nella formula di colonna nel ciclo forGrazie Jim, funziona perfettamente!Ri: Per gruppi nella formula di colonna nel ciclo for

Sembra che JMP abbia un problema con l'utilizzo della sola funzione Column().Tuttavia, la funzione As Column() risolve il problema.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean( as Column( __colname__ ), :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev( as Column( __colname__ ) ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( as Column( __colname__ ) ) / Col Mean( as Column( __colname__ ) ) )
     );
    ),
   Expr( __colname__ ), colnames[i]
  )
 )
);

Dato che stai utilizzando la funzione Substitute(), potresti anche rimuovere le funzioni As Column() o Column() e sostituire __colname__ con il riferimento effettivo alla colonna di :theactualcolumnname. Vedi sotto

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Column( "Old", Character, Formula( If( :age >= 14, "Old", "Young" ) ) );

colnames = dt << get column names( numeric, string );
For( i = 1, i <= N Items( colnames ), i++,
 Eval(
  Substitute(
    Expr(
     New Column( Char( colnames[i] ) || " mean",
      Numeric,
      Formula( Col Mean(  __colname__ , :old ) )
     );
     New Column( Char( colnames[i] ) || " STD DEV",
      Numeric,
      Formula( Col Std Dev(  __colname__  ) )
     );
     New Column( Char( colnames[i] ) || " CV%",
      Numeric,
      Format( "Percent", 2 ),
      Formula( Col Std Dev( __colname__  ) / Col Mean(  __colname__  ) )
     );
    ),
   Expr( __colname__ ), Parse( ":" || colnames[i] )
  )
 )
);