238599_it-IT

liliconcom

Aggiungi la riga H dello script grafico con la variabile

Ciao a tutti,

Sto cercando di aggiungere una linea orizzontale all'oggetto del generatore di grafici con variabile, in questo modo funziona

 x =  139.4;
 Show( x );   //x = 139.4;
 gbReport[Framebox( 1 )] << addGraphicsScript(

  H Line( x )
 );
 

 

Ma se sto facendo qualcosa del genere

 

TR1_row = dt_lims << get selected rows;

TR1 = Column( dt_lims, "CL" )[TR1_row] ;

gbReport[Framebox( 1 )] << addGraphicsScript(
 
  H Line(TR1 )
 );&nbsp;&nbsp;

Non funziona, qualche idea?

Ri: Aggiunta della riga H dello script grafico con variabile

@avner8943 ,

 

In allegato è presente uno script che utilizza un gestore RowState per modificare i limiti.

Names Default to Here(1);

dt = Open("$Sample_Data/Big Class.jmp");
dt << sort(By(:sex, :age), Replace Table(1));
dt << New Column( "Order", Numeric);
dt:Order << Set Each Value( If( row()==1 | :sex != lag(:sex,1), 1, lag(:Order,1) +1)) ; 
dtsum = dt << Summary( Group(:sex), Min(:height), mean(:height), Max(:height));

dtlims = dtsum << Stack(
 columns(
  :Name( "Min(height)" ),
  :Name( "Mean(height)" ),
  :Name( "Max(height)" )
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Limits" )
);

Close(NoSave, dtsum);
f= Function({a}, {TR1, i},
 print(a, fb);
// show(a, fb);
    for(i=1, i<=nitems(fb), i++,
     Try( fb[i] << Remove Graphics Script (1) )
    );
    TR1 = :Limits[dtlims << get selected rows];
    Eval (EvalExpr( fb << Add Graphics Script( H Line( Expr( TR1) ) ) ) ); 
);


gb = dt << Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :Order ), Y( :height ), Group X(:sex) ),
 Elements( Points( X, Y, Legend( 3 ) ), Line( X, Y, Legend( 5 ) ) )
);

fb = gb << Xpath("//FrameBox");

rs = dtlims <<  Make RowState Handler(f );

Seleziona una o più righe o deseleziona tutte le selezioni di riga e visualizza le modifiche su tutti i framebox.

 

 

Questo script è stato testato su JMP 14 e 15. In allegato è riportata una leggera modifica dello script alla riga 26 in modo che lo script funzioni su JMP 13.

 

Quindi deve esserci qualcos'altro che non va nel tuo script, perché funziona con uno script RowState Handler.

Ri: Aggiunta della riga H dello script grafico con variabile

Forse perché lo faccio all'interno di una funzione e chiamo questa funzione da MakeRowStateHandler, quando lo provo all'esterno della funzione funziona.

Ri: Aggiunta della riga H dello script grafico con variabile

@avner8943 ,

 

Ecco uno script che utilizza la tabella dei dati di esempio JMP Big Class e utilizza selettivamente solo i maschi e aggiunge 3 limiti contemporaneamente.   

 

Names Default to Here(1);

dt = Open("$Sample_Data/Big Class.jmp");
dt << sort(By(:sex, :age), Replace Table(1));
dt << New Column( "Order", Numeric);
dt:Order << Set Each Value( If( row()==1 | :sex != lag(:sex,1), 1, lag(:Order,1) +1)) ; 
dtsum = dt << Summary( Group(:sex), Min(:height), mean(:height), Max(:height));

dtlims = dtsum << Stack(
 columns(
  :Name( "Min(height)" ),
  :Name( "Mean(height)" ),
  :Name( "Max(height)" )
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Limits" )
);

Close(NoSave, dtsum);

TR1_row = dtlims << get rows where( :sex =="M");

TR1 = column(dtlims, "Limits")[TR1_row];

gb = dt << Graph Builder( where (:sex=="M"),
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :Order ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Line( X, Y, Legend( 5 ) ) )
);

gbreport = report(gb);

gbreport[FrameBox(1)] << Add Graphics Script( HLine( TR1 ) );

Produce questa trama.

 

 

Non sono sicuro di quale sia il problema, a meno che non ci siano righe selezionate.

 

Buona fortuna!

 

Ri: Aggiunta della riga H dello script grafico con variabileFunziona, ma come posso adattarlo al mio script che prende valore da una cella specifica nella tabella JMP.Ri: Aggiunta della riga H dello script grafico con variabile

@avner8943 ,

 

La sintassi per H Line() è H Line(y), H Line( x1, x2, y). Inoltre, se hai un vettore di valori, prova questo script.

Names Default To Here( 1 );
v = [10, 50, 20];
New Window( "Example",
 Graph Box(
  Pen Size( 2 );
  H Line( v );
 )
);

Produce questa trama:

 

Controlla se questo script funziona per te.In caso contrario, specificare quale versione di JMP e sistema operativo si sta utilizzando.