236548_it-IT

liliconcom

Lo script per avere caselle di testo di dimensioni fisse

Ciao,

Devo generare una finestra in cui il testo in alto sia sempre un'altezza fissa, con un'altra casella di testo in basso che sia un'altezza fissa diversa, ecc. In questo modo vengono impilate 5 caselle di testo diverse. L'idea è che quando viene visualizzata la finestra, le caselle di testo sono sempre nelle stesse posizioni, indipendentemente dalla modifica del testo.

Qualsiasi aiuto è molto apprezzato.

Ecco il mio codice attualmente senza successo:

VALconv = 37.795275591;
VALwidth = 6*VALconv;
tb1 = Text Box(STRname);
tb1 << Set Font("Lucida Handwriting",18,"bold");
tb1 << Set Max Size(VALwidth,1.8*VALconv);
tb1 << Set Width(VALwidth);
tb1 << Set Height(1.8*VALconv);
tb1 << Set Wrap(VALwidth);
hb1 = H List Box(tb1);
hb1 << Set Max Size(VALwidth,1.8*VALconv);
hb1 << Set Min Size(VALwidth,1.8*VALconv);

tb2 = Text Box(STRch1);
tb2 << Set Font("Arial",12);
tb2 << Set Max Size(VALwidth,2*VALconv);
tb2 << Set Width(VALwidth);
tb2 << Set Height(2*VALconv);
tb2 << Set Wrap(VALwidth);
hb2 = H List Box(tb2);
hb2 << Set Max Size(VALwidth,2*VALconv);
hb2 << Set Min Size(VALwidth,2*VALconv);

tb3 = Text Box(STRch2);
tb3 << Set Font("Arial",12);
tb3 << Set Max Size(VALwidth,2*VALconv);
tb3 << Set Width(VALwidth);
tb3 << Set Height(2*VALconv);
tb3 << Set Wrap(VALwidth);
hb3 = H List Box(tb3);
hb3 << Set Max Size(VALwidth,2*VALconv);
hb3 << Set Min Size(VALwidth,2*VALconv);

tb4 = Text Box(STRch3);
tb4 << Set Font("Arial",12);
tb4 << Set Max Size(VALwidth,2*VALconv);
tb4 << Set Width(VALwidth);
tb4 << Set Height(2*VALconv);
tb4 << Set Wrap(VALwidth);
hb4 = H List Box(tb4);
hb4 << Set Max Size(VALwidth,2*VALconv);
hb4 << Set Min Size(VALwidth,2*VALconv);

tb5 = Text Box(STRtype);
tb5 << Set Font("Arial",12);
tb5 << Set Max Size(VALwidth,1*VALconv);
tb5 << Set Width(VALwidth);
tb5 << Set Height(1*VALconv);
tb5 << Set Wrap(VALwidth);
hb5 = H List Box(tb5);
hb5 << Set Max Size(VALwidth,1*VALconv);
hb5 << Set Min Size(VALwidth,2*VALconv);

NW = New Window("NW", hb1,hb2,hb3,hb4,hb5);<BR />

 

Ri: Script per avere caselle di testo di dimensioni fisse

Non sono sicuro di capire perché questo codice non ha esito positivo.  Spiegare come si presenta l'output.  A proposito, non hai bisogno di tutte quelle caselle dell'elenco H poiché non stai posizionando nulla in orizzontale accanto alle caselle di testo.  Se sei preoccupato che la larghezza sia la stessa, puoi usare LINEUP BOX.

strname = "Hello World";
strch1  = "Fubarski";
strch2  = strch1;
strch3  = strch1;
strtype = "String Type";

VALconv = 37.795275591;
VALwidth = 6*VALconv;
tb1 = Text Box(STRname);
tb1 << Set Font("Lucida Handwriting",18,"bold") << Set Max Size(VALwidth,1.8*VALconv);
tb1 << Set Width(VALwidth) << Set Height(1.8*VALconv) << Set Wrap(VALwidth);

tb2 = Text Box(STRch1);
tb2 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb2 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb3 = Text Box(STRch2);
tb3 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb3 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb4 = Text Box(STRch3);
tb4 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb4 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb5 = Text Box(STRtype);
tb5 << Set Font("Arial",12) << Set Max Size(VALwidth,1*VALconv);
tb5 << Set Width(VALwidth) << Set Height(1*VALconv) << Set Wrap(VALwidth);

NW = New Window("NW", lineup box(ncol(1), tb1,tb2,tb3,tb4,tb5));

Ri: Script per avere caselle di testo di dimensioni fisse

Se si desidera che tutte le caselle di testo abbiano la stessa altezza, è possibile inserire una casella di testo a due righe (due LF) accanto a ciascuna delle caselle di testo.  Prova questo:

strname = "Hello World";
strch1  = "Fubarski";
strch2  = strch1;
strch3  = strch1;
strtype = "String Type";

VALconv = 37.795275591;
VALwidth = 6*VALconv;
tb1 = Text Box(STRname);
tb1 << Set Font("Lucida Handwriting",18,"bold") << Set Max Size(VALwidth,1.8*VALconv);
tb1 << Set Width(VALwidth) << Set Height(1.8*VALconv) << Set Wrap(VALwidth);

tb2 = Text Box(STRch1);
tb2 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb2 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb3 = Text Box(STRch2);
tb3 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb3 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb4 = Text Box(STRch3);
tb4 << Set Font("Arial",12) << Set Max Size(VALwidth,2*VALconv);
tb4 << Set Width(VALwidth) << Set Height(2*VALconv) << Set Wrap(VALwidth);

tb5 = Text Box(STRtype);
tb5 << Set Font("Arial",12) << Set Max Size(VALwidth,1*VALconv);
tb5 << Set Width(VALwidth) << Set Height(1*VALconv) << Set Wrap(VALwidth);

tb0 = text box("

");

NW = New Window("NW", lineup box(ncol(2), tb1, tb0, tb2, tb0, tb3, tb0, tb4, tb0, tb5, tb0));

Ri: Script per avere caselle di testo di dimensioni fisse

Mi dispiace che avrei dovuto essere più specifico e meno vago.

Sto cercando di ottenere sempre il layout esatto come in questa immagine, con lo "spazio bianco" necessario, quindi il testo 2 inizia sempre 1,8 cm se il testo 1 è corto, ecc.

VALconv è quello che credo sia il rapporto di conversione da pixel a cm di un rapido google.

Inizialmente erano caselle di riepilogo H, poiché in una prossima iterazione potrei voler mescolare testo e immagini all'interno di una "scatola" che ha una dimensione fissa (ad esempio 1,8 cm per 6 cm), ma che è un desiderio non avere un must e il mio obiettivo principale è farlo funzionare prima con il testo normale.

Ri: Script per avere caselle di testo di dimensioni fisse

È disponibile un messaggio a dimensione fissa per TextBox.  Forse, qualcosa come il seguente avrebbe funzionato per te. Nota: ho aggiunto BorderBox in modo da poter vedere più chiaramente le dimensioni delle TextBox.

 

strname = "Text1";
strch1 = "Text2";
strch2 = "Text3";
strch3 = "Text4";
strtype = "Text5";

VALconv = 37.795275591;
VALwidth = 6 * VALconv;
tb1 = Text Box( STRname );
tb1 << Set Font( "Lucida Handwriting", 18, "bold" ) << Fixed Size( 1, VALwidth, 1.8 * VALconv );

tb2 = Text Box( STRch1 );
tb2 << Set Font( "Arial", 12 ) << Fixed Size( 1, VALwidth, 2 * VALconv );

tb3 = Text Box( STRch2 );
tb3 << Set Font( "Arial", 12 ) << Fixed Size( 1, VALwidth, 2 * VALconv );

tb4 = Text Box( STRch3 );
tb4 << Set Font( "Arial", 12 ) << Fixed Size( 1, VALwidth, 2 * VALconv );

tb5 = Text Box( STRtype );
tb5 << Set Font( "Arial", 12 ) << Fixed Size( 1, VALwidth, 1 * VALconv );

NW = New Window( "NW",
 Lineup Box( N Col( 1 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb1 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb2 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb3 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb4 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb5 )
 )
);

Spero che aiuti!

Ri: Script per avere caselle di testo di dimensioni fisse

Costruire cosa @Wendy_Murphrey disse.  A volte farò in modo che le funzioni restituiscano oggetti predefiniti come un modo falso di sottoclasse.  

 

Names Default to Here( 1 );
strname = "Text1";
strch1 = "Text2";
strch2 = "Text3";
strch3 = "Text4";
strtype = "Text5";

Lucida_Textbox = function({text}, 
 {DEFAULT LOCAL}, 
 VALconv = 37.795275591;
 VALwidth = 6 * VALconv;
 tb = Text Box( text );
 tb << Set Font( "Lucida Handwriting", 18, "bold" ) << Fixed Size( 1, VALwidth, 1.8 * VALconv );
 return(tb);
);

Arial_Textbox = function({text}, 
 {DEFAULT LOCAL}, 
 VALconv = 37.795275591;
 VALwidth = 6 * VALconv;
 tb = Text Box( text );
 tb << Set Font( "Arial", 12 ) << Fixed Size( 1, VALwidth, 2 * VALconv );
 return(tb);
);

tb1 = Lucida_Textbox( STRname );

tb2 = Arial_Textbox( STRch1 );

tb3 = Arial_Textbox( STRch2 );

tb4 = Arial_Textbox( STRch3 );

tb5 = Arial_Textbox( STRtype );

NW = New Window( "NW",
 Lineup Box( N Col( 1 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb1 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb2 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb3 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb4 ),
  Border Box( Left( 0 ), Right( 0 ), Top( 0 ), Bottom( 0 ), Sides( 15 ), tb5 )
 )
);