234198_ja-JP

liliconcom

GUIの「フィルター列セレクター」から「選択した列を移動」を呼び出す。

GUIから[選択した列を移動]メニューを呼び出そうとしています。

 

このコードはそれを呼び出しますが、テーブルを再編成しません（おそらくMoveSelectedColumnsの使い方が間違っているためです）。

 

MoveButtonPress=Function({this},
        // colListData is a Filter Col Selector in a GUI
 selectedElements = colListData << GetSelected;
 DataTable1 << move selected columns(selectedElements, after()); // TODO fix this
 colListData << Reset; //refresh selector
 colListData << NameContains (" "); // reactivates filter
);

 

Re：GUIの「フィルター列セレクター」から「選択した列を移動」を呼び出す。

「選択を取得」ではなく「GetSelectedColumns」を使用するようにコードを少し変更しました。これがうまくいくかどうか教えてください。

DataTable1=Open("$SAMPLE_DATA/Big Class.jmp");

nw=New Window("Move Selected Columns button",
 Button Box("Move Selected Columns",
 
 selectedElements = DataTable1 << GetSelectedColumns;
 DataTable1 << move selected columns(selectedElements, after(:name));
  
 )
);

Re：GUIの「フィルター列セレクター」から「選択した列を移動」を呼び出す。コードを使用するとエラーが発生します。

「認識されないキーワード」。

一方、「after（：name）」は他のデータセットでは機能しません。列の場所を示すために列の名前を使用しているためです。

次の2つのオプションがあります。
-最初の列名を取得し、1つ上または下に移動します。
-または、列の移動のメニューを開き、「最初へ」、「最後へ」、「タグのリスト」を選択します。


Re：GUIの「フィルター列セレクター」から「選択した列を移動」を呼び出す。

「選択された列を移動」機能では、列名ではなく入力として列参照が必要なため、「認識されないキーワード」エラーが表示されると思います。  以下のコードをご覧ください。  「後」列を選択する機能など、いくつかの機能を追加しました。  これはもっと便利ですか？

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );



nw = New Window( "Move Selected Columns button", 

 H List Box(
  V List Box(
   Text Box( "Select Columns to Move" ),
   columns_to_move = Col List Box( Data Table( dt ), all )
  ),
  V List Box(
   Text Box( "Before Before or After Selected Column" ),
   after_column_list = Col List Box( Data Table( dt ), all )
  )
 ),
 H List Box(
  Button Box( "Move To First", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )//For-loop used to convert list of Column Names to Column References
   );
   dt << move selected columns( colList, To First );//Move Columns to First
  
  ),
  Button Box( "Move To Last", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )
   );
   dt << move selected columns( colList, To Last );//Move Columns to First
  ),
  Button Box( "Move After Column", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   aftercol_string = after_column_list << GetSelected;//Get Column to move after
   aftercol_ref = Column( dt, aftercol_string[1] );//Column reference - only first item in case someone chose more than one
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )
   );
   dt << move selected columns( colList, after( aftercol_ref ) );
  
  )
 )
 
);