234198_it-IT

liliconcom

Chiamata "Sposta colonne selezionate" da un "Selettore colonne filtro" in una GUI.

Sto provando a chiamare il menu Sposta colonne selezionate da una GUI.

 

Mentre questo codice lo chiama, non riorganizza la tabella (probabilmente a causa dell'utilizzo errato di MoveSelectedColumns ...)

 

MoveButtonPress=Function({this},
        // colListData is a Filter Col Selector in a GUI
 selectedElements = colListData << GetSelected;
 DataTable1 << move selected columns(selectedElements, after()); // TODO fix this
 colListData << Reset; //refresh selector
 colListData << NameContains (" "); // reactivates filter
);

 

Ri: Chiamare "Sposta colonne selezionate" da un "Selettore colonne filtro" in una GUI.

Ho modificato un po 'il codice per utilizzare "GetSelectedColumns" anziché "Get Selected". Per favore fatemi sapere se questo funziona per voi?

DataTable1=Open("$SAMPLE_DATA/Big Class.jmp");

nw=New Window("Move Selected Columns button",
 Button Box("Move Selected Columns",
 
 selectedElements = DataTable1 << GetSelectedColumns;
 DataTable1 << move selected columns(selectedElements, after(:name));
  
 )
);

Ri: Chiamare "Sposta colonne selezionate" da un "Selettore colonne filtro" in una GUI.Viene visualizzato un errore durante l'utilizzo del codice:

"Parola chiave non riconosciuta".

D'altra parte, 'after (: name)' non funzionerà in altri set di dati, poiché stiamo usando il nome della colonna come indicazione su dove inserirlo.

Vedo due opzioni:
- Ottieni il nome della prima colonna e spostalo su / giù di una posizione.
- Oppure apri il menu delle colonne di spostamento e seleziona Per primo, Per ultimo, dopo: elenco di tag.


Ri: Chiamare "Sposta colonne selezionate" da un "Selettore colonne filtro" in una GUI.

Credo che stai ricevendo l'errore "parola chiave non riconosciuta" perché la funzione "Sposta colonne selezionate" richiede un riferimento di colonna come input e non un nome di colonna.  Si prega di dare un'occhiata al codice qui sotto.  Ho aggiunto alcune funzionalità, inclusa la possibilità di scegliere una colonna "dopo".  Questo è più utile?

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );



nw = New Window( "Move Selected Columns button", 

 H List Box(
  V List Box(
   Text Box( "Select Columns to Move" ),
   columns_to_move = Col List Box( Data Table( dt ), all )
  ),
  V List Box(
   Text Box( "Before Before or After Selected Column" ),
   after_column_list = Col List Box( Data Table( dt ), all )
  )
 ),
 H List Box(
  Button Box( "Move To First", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )//For-loop used to convert list of Column Names to Column References
   );
   dt << move selected columns( colList, To First );//Move Columns to First
  
  ),
  Button Box( "Move To Last", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )
   );
   dt << move selected columns( colList, To Last );//Move Columns to First
  ),
  Button Box( "Move After Column", 
 
   MoveColumns = columns_to_move << GetSelected;//Get List Of Column Names
   dt << Select Columns( MoveColumns );//Select Columns
 
   aftercol_string = after_column_list << GetSelected;//Get Column to move after
   aftercol_ref = Column( dt, aftercol_string[1] );//Column reference - only first item in case someone chose more than one
 
   colList = {};//List to hold Column References
   For( i = 1, i <= N Items( MoveColumns ), i++, 
 
    colList[i] = Column( dt, MoveColumns[i] )
   );
   dt << move selected columns( colList, after( aftercol_ref ) );
  
  )
 )
 
);