232631_fr-FR

liliconcom

Somme cumulée des lignes dans la nouvelle colonne par différentes colonnes

dt = Current Data Table();


// List of column names for the table

col_names = dt << get column names( string );


// Create cumulative sum of each D

looking_for_channel_1 = "D";

For( i = 1, i <= N Items( col_names ), i++,

// search column names for "D"

If( Starts With( col_names[i], looking_for_channel_1 ),

new_col = dt << New Column( Char( col_names[i] ) || ">=",
Numeric,
.................................
);

);

);

Chers tous,

Je suis un nouveau scripteur essayant de résoudre un problème actuel. Je ne connais pas très bien la syntaxe mais je souhaite parcourir les colonnes et les lignes pour calculer la somme cumulée pour chaque outil et chaque ligne et enregistrer le résultat dans une nouvelle colonne. J'ai joint un tableau de données qui montre la solution.

 

Merci beaucoup pour tout commentaire fourni.

BR

Martin

Re : Somme cumulée des lignes dans une nouvelle colonne par différentes colonnes

Voici une autre approche, créant simplement les nouvelles colonnes à l'aide de colonnes de formules

Names Default To Here( 1 );

// This JSL assume the table contains only the Tool column,
// followed by the Dnnn columns.  No cummulative columns have been
// created yet
dt = Current Data Table();

totCol = N Cols( dt );

// Loop across the columns creating the new cumulative sums
For( i = 2, i <= totCol, i++,
 Eval(
  Substitute(
    Expr(

     dt << New Column( __newname__, formula( __formula__ ) )
    ),
   Expr( __newname__ ), Column( dt, i ) << get name || ">=",
   Expr( __formula__ ),
    If( i == 2,
     Parse( Column( dt, i ) << get name ),
     Parse(
      "sum( :Name(\!"" || char( Column( dt, i - 1 ) << get name ) || ">=\!"), " || char( Column( dt, i ) << get name )
       || ")"
     )
    )
  )
 )
);

Re : Somme cumulée des lignes dans une nouvelle colonne par différentes colonnes

J'ai adopté une approche différente pour résoudre votre problème.Parcourir les données, accumuler les données comme vous le proposez deviendra assez lent avec beaucoup de colonnes et de lignes.L'utilisation des fonctions JMP intégrées sera beaucoup plus rapide.Vous trouverez ci-dessous un script qui transpose les données dans une grande table de données pour effectuer le traitement, à l'aide de la fonction intégrée Col Cumulative Sum(), puis transpose les données au format large une fois le traitement terminé.

names default to here(1);
dt=current data table();

// Transform the data into a long table from the current wide table
// to allow for faster processing using the built in column function
//      col cumulative sum()
dtStack = dt << Stack(
 columns( :D300, :D200, :D100, :D50, :D10 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ),
 Name( "Non-stacked columns" )(Keep( :Tool, :Column 13 ))
);

// Add a new column to insure an alphbetical ordering of the original
// data table
dtStack << New Column( "Row Number",
 Character,
 "Nominal",
 Formula(
  If( Lag( :Tool ) != :Tool,
   counter = 0
  );
  counter = counter + 1;
  result = Substr( "00", Length( Char( counter ) ) - 3 ) || Char( counter )
   || " " || :Label;
 )
);

// Add the Cumulative Sum column
dtStack << New Column( "xx",
 Numeric,
 "Continuous",
 Format( "Best", 12 ),
 Formula( Col Cumulative Sum( :Data, :Tool ) ),
 Set Selected
);

// Transpose the data back into a wide format 
dtFinal = dtStack << Split(
 Split By( :Row Number ),
 Split( :Data, :Name( "xx" ) ),
 Group( :Tool ),
 Remaining Columns( Drop All ),
 Sort by Column Property
);

// Close the nolonger needed stack data table
close(dtStack,nosave);

// Pass across the column names adjusting them back to the desired form
For( i = 2, i <= N Cols( dtFinal ), i++,
 If(
  Word( 1, Column( dtFinal, i ) << get name, " " ) == "Data",
   Column( dtFinal, i ) << set name( Substr( Column( dtFinal, i ) << get name, 10 ) )
 ,
  Word( 1, Column( dtFinal, i ) << get name, " " ) == "xx",
   Column( dtFinal, i ) << set name( Substr( Column( dtFinal, i ) << get name, 8 ) || ">=" )
 )
);