232437_fr-FR

liliconcom

Ppt

Bonjour, j'aimerais poser une question.

nw = Outline Box( wname,
 V List Box(
  Button Box( "Save All", sstat = saveall( 1, 330, 1, wname, sdir ) ),
  Spacer Box( Size( 1, 5 ) ),
  Tab Box( "Sat", V List Box( Button Box( "Save Tab" ), satplot( satp, grpname, grpname2, groupList ) ) )
 )
);
dt << Select All Rows;


title = Outline Box( "Plots by Design" );
title << append( nw[1] << get picture );
For( l = 1, l <= N Items( nw ), l++,
 title << append( nw[l] << get picture )
);
title << save presentation( "C:\Users\Desktop\Final.pptx", append );
Open( "C:\Users\Desktop\Final.pptx" );

Mon résultat souhaité est un tracé par diapositive, mais le résultat est une image longue de tous les graphiques.

Re: Ppt

Vous semblez ne pas comprendre la section nw = de votre code.  À l'intérieur de la zone de contour, vous avez des objets destinés à être des objets visibles. Toutefois, la zone de contour ne sera visible que si elle est placée dans une nouvelle fenêtre () ou un journal.  

En outre, vous faites référence à "satplot" mais cette fonction n'est pas contenue dans votre code.

Enfin, vous faites référence à nw [l] dans votre image get.  Étant donné votre code, je ne suis pas sûr que vous auriez jamais plus d'un élément dans votre nouvelle référence.

Re: Ppt

@ skyzvoir0001 ,

 

Comme @txnelson , Jim, je ne suis pas sûr de ce que vous essayez de faire. En supposant que nw soit une liste d'objets d'affichage JMP, voici un script qui pourrait être proche de ce que vous voulez faire. Remarque: ce script enregistre le premier tracé sous forme de fichier PPT. Ensuite, chaque graphique suivant est ajouté à la présentation PPT.

 

Votre code crée des graphiques ajoutés dans une grande boîte de contour. JMP écrit au format PPT une page par zone de plan, d'où un long graphique.

Names Default to Here(1);

dt = Open("$Sample_Data/Fitness.jmp");

nw = Bivariate(
  Y( :Runtime, :RunPulse, :MaxPulse ),
  X( :Oxy ),
  Group By( :Sex ),
  Fit Line( {Report( 0 )} ),
  SendToReport(
   Dispatch(
    {},
    "Bivar Plot",
    FrameBox,
    {Row Legend(
     :Sex,
     Color( 1 ),
     Color Theme( "SAS Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   )
  )
 );

np = N Items(nw);
title = Outline Box( "Plots by Design - 1 of " || char(np) );
title << append( nw[1] << get picture );
title << save presentation( "C:\Users\gz\Desktop\Final.pptx" );

For( l = 2, l <= N Items( nw ), l++,
   title = Outline Box( EvalInsert("Plots by Design - ^l^ of  ^np^")  );
   title << append( nw[l] << get picture );
   title << save presentation( "C:\Users\gz\Desktop\Final.pptx", append );

);
Open( "C:\Users\gz\Desktop\Final.pptx" );