232437_en-US

liliconcom

Ppt

Hi, I'd like to ask a question.

nw = Outline Box( wname,
 V List Box(
  Button Box( "Save All", sstat = saveall( 1, 330, 1, wname, sdir ) ),
  Spacer Box( Size( 1, 5 ) ),
  Tab Box( "Sat", V List Box( Button Box( "Save Tab" ), satplot( satp, grpname, grpname2, groupList ) ) )
 )
);
dt << Select All Rows;


title = Outline Box( "Plots by Design" );
title << append( nw[1] << get picture );
For( l = 1, l <= N Items( nw ), l++,
 title << append( nw[l] << get picture )
);
title << save presentation( "C:\Users\Desktop\Final.pptx", append );
Open( "C:\Users\Desktop\Final.pptx" );

My desired output is one plot per slide but the output is a long image of all graphs

Re: Ppt

You appear to not understand the nw= section of your code.  Inside of the Outline Box, you have objects that are intended to be visible objects, however, the Outline Box will not be visible unless placed into a New Window() or a Journal.  

Also, you reference "satplot" but that function is not contained in your code.

Finally, you are referencing nw[l] in your get picture.  I am not sure, given your code, that you would ever have more than one element in your nw reference.

Re: Ppt

@skyzvoir0001,

 

Like @txnelson, Jim, I am not sure what you are trying to do. Assuming nw is a list of JMP display objects, here is a script that might be close to what you want to do. Note: this script saves the first plot as a PPT file. Then each subsequent plot is appended to the PPT presentation.

 

Your code creates appended graphs in one large outlinebox. JMP writes to PPT one page per outline box, hence one long graph.

Names Default to Here(1);

dt = Open("$Sample_Data/Fitness.jmp");

nw = Bivariate(
  Y( :Runtime, :RunPulse, :MaxPulse ),
  X( :Oxy ),
  Group By( :Sex ),
  Fit Line( {Report( 0 )} ),
  SendToReport(
   Dispatch(
    {},
    "Bivar Plot",
    FrameBox,
    {Row Legend(
     :Sex,
     Color( 1 ),
     Color Theme( "SAS Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   )
  )
 );

np = N Items(nw);
title = Outline Box( "Plots by Design - 1 of " || char(np) );
title << append( nw[1] << get picture );
title << save presentation( "C:\Users\gz\Desktop\Final.pptx" );

For( l = 2, l <= N Items( nw ), l++,
   title = Outline Box( EvalInsert("Plots by Design - ^l^ of  ^np^")  );
   title << append( nw[l] << get picture );
   title << save presentation( "C:\Users\gz\Desktop\Final.pptx", append );

);
Open( "C:\Users\gz\Desktop\Final.pptx" );