232299_es-ES

liliconcom

Crear una lista de valores correspondientes a la lista de columnas

Estoy creando una lista de posibles nombres de columnas que se pueden encontrar en una de las muchas tablas de datos con las que se trabaja, creando una lista real de columnas que se encuentran en la tabla de datos abierta y luego intentando crear una lista de valores correspondientes a la lista de columnas real.Sin embargo, cuando ejecuto el siguiente código, toma el valor de la primera columna de la lista para todas las columnas enumeradas por las que paso.Este código da como resultado una lista = {13.975, 13.975} en lugar de {13.975, 105}.Probé varias iteraciones para esto pero no puedo obtener los valores correctos.Cualquier sugerencia será muy apreciada.

Clear Log();

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

dt_col_name_list = dt << Get Column Names( String );

dtsum = dt << Summary( 
 Mean( Eval( dt_col_name_list ) ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" )
);


// Potential column name list
pot_col_list = {"age", "mass", "height", "length" };
dtsum_col_name_list = dtsum << Get Column Names( String );
show(dtsum_col_name_list);

// Create empty list to hold names of the those measurement variables found in data table
act_col_list = {};
col_list_cnt = {};

// Run through data table column names and put those that match measurement variable list into new list
For( i = 1, i <= N Items( pot_col_list ), i++,
 If( Contains( dtsum_col_name_list, pot_col_list[i] ),
  Insert Into( act_col_list, pot_col_list[i] );
  Insert Into( col_list_cnt, dtsum:pot_col_list[1,i] );
 )
);

Show( col_list_cnt );

Re: Crear lista de valores correspondientes a lista de columnas

Eso lo hizo txnelson,

 

Gracias por echar un vistazo y ayudarme a corregir mi error de sintaxis.

Re: Crear lista de valores correspondientes a lista de columnas

La referencia utilizada para obtener el valor de pot_col_list no es válida; consulte a continuación una corrección que parece funcionar

names default to here(1);
Clear Log();

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA\Big Class.jmp" );

dt_col_name_list = dt << Get Column Names( String );

dtsum = dt << Summary( 
 Mean( Eval( dt_col_name_list ) ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" )
);


// Potential column name list
pot_col_list = {"age", "mass", "height", "length" };
dtsum_col_name_list = dtsum << Get Column Names( String );
show(dtsum_col_name_list);

// Create empty list to hold names of the those measurement variables found in data table
act_col_list = {};
col_list_cnt = {};

// Run through data table column names and put those that match measurement variable list into new list
For( i = 1, i <= N Items( pot_col_list ), i++,
 If( Contains( dtsum_col_name_list, pot_col_list[i] ),
  Insert Into( act_col_list, pot_col_list[i] );
  Insert Into( col_list_cnt, column(dtsum,pot_col_list[i])[1] );
 )
);

Show( col_list_cnt );