Get random numbers upon radio button selection

UserID16644

Hi, 

I am trying to produce random numbers upon radio box selection and produce a number of combination according to user input. So far, this is what I only have.

win = New Window( "LOTTO",
	<<Modal,
	Panel Box( "Select one",
		rb = Radio Box( 
				{"6/42", "6/45", "6/49", "6/55", "6/58"} ),
			Text Box( "Enter Number of Combinations" ),
			H List Box( Text Box( "" ), 
				textbox_value = Number Edit Box(1) ),
		Button Box( "Ok", 
					rb_result = rb << get; 
					random = textbox_value << get; 
					
		);	
	) 
);

Mark_Bailey

It is still not clear to me what you want to do but see if this result is close.

 

Names Default To Here( 1 );

win = New Window( "LOTTO", << Modal,
	Panel Box( "Select one",
		rb = Radio Box( {"6/42", "6/45", "6/49", "6/55", "6/58"} ),
		H List Box(
			Text Box( "Enter Number of Combinations" ),
			textbox_value = Number Edit Box( 1 )
		)
	),
	H List Box(
		Button Box( "OK",
			rb_result = rb << Get;
			random = textbox_value << Get; 
					
		),
		Button Box( "Cancel" )
	)
);

If( win["Button"] == -1,
	Throw( "User cancelled" )
);

dt = New Table( "Lotto" );

For( c = 1, c <= random, c++,
	dt << New Column( "Draw " || Char( c ),
		"Numeric",
		"Continuous",
		Values(
			Choose( rb_result,
				J( 6, 1, Random Integer( 1, 42 ) ),
				J( 6, 1, Random Integer( 1, 45 ) ),
				J( 6, 1, Random Integer( 1, 49 ) ),
				J( 6, 1, Random Integer( 1, 55 ) ),
				J( 6, 1, Random Integer( 1, 58 ) )
			)
		)
	);
);