Ich habe die Diskussionsbeiträge durchsucht und JMP zuerst als TXT-Datei gespeichert und dann den TXT-Namen in CSV geändert.
Aber meine JMP-Standardeinstellung aktiviert nicht „Tabellenüberschriften exportieren“.
Wie kann die JSL als CSV-Datei mit dem Spaltennamen gespeichert werden?
Ich habe „Export Table Headers(1)“ in den Code eingefügt, was nicht funktioniert hat.
Danke!
@lwx228 ,
Ihr Screenshot sieht aus wie eine ältere Version von JMP.Bitte geben Sie die JMP-Version und das Betriebssystem (Windows?) an, das Sie verwenden.
In JMP 13 und späteren Versionen können Sie einfach das CSV-Format speichern. Möglicherweise ist es für Ihre Version nicht verfügbar.Wenn ja, ist dies die beste Methode.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Save( "c:\temp\deleteme2 Big Class.csv" ); // convert to CSV format
Close( dt, "NoSave" );
Das Speichern einer Textdatei erfordert das Ändern der Exporteinstellungen Präferenz. Ich empfehle, die aktuellen Einstellungen zu speichern, zu ändern, die Textdatei(en) zu exportieren/speichern und dann die Einstellungen zurückzusetzen.Hier ist ein Skript, um das zu tun.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
pathout = "c:\temp\";
ofid = "BigClass_csv";
// Save as text with comma delimiters
// Get user Export Preferences
xptPref = Get Preferences( Export Settings );
// Set desired Export Preferences
Preferences(
ExportSettings(
End Of Line( CRLF ),
End Of Field( Comma ), //optionally try: Tab|Space|Other("|")|Other("^") etc
Export Table Headers( 1 )
)
);
// Save as .txt
dt << Save( pathOut || ofid || ".txt" );
// Reset user Export Preferences
Eval( xptPref );
// xptPref; // works as well.
Close(dt,NoSave);
Rename File( pathout || ofid || ".txt", ofid || ".csv");.
Ich hoffe, eines davon funktioniert für Sie.
