J'ai recherché les messages de discussion et enregistré JMP en tant que fichier TXT, puis j'ai changé le nom TXT en CSV.
Mais mon défaut JMP ne coche pas "Exporter les en-têtes de table".
Comment le JSL peut-il être enregistré sous forme de fichier CSV avec le nom de la colonne ?
J'ai ajouté "Export Table Headers(1)" dans le code, ce qui n'a pas fonctionné.
Merci!
@lwx228 ,
Votre capture d'écran ressemble à une ancienne version de JMP.Veuillez fournir la version de JMP et le système d'exploitation (Windows ?) que vous utilisez.
Dans JMP 13 et versions ultérieures, vous pouvez simplement enregistrer le format .csv. Il n'est peut-être pas disponible pour votre version.Si c'est le cas, c'est la meilleure méthode.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Save( "c:\temp\deleteme2 Big Class.csv" ); // convert to CSV format
Close( dt, "NoSave" );
L'enregistrement d'un fichier texte nécessite de modifier le Paramètres d'exportation préférence. Je recommande d'enregistrer les préférences actuelles, de les modifier, d'exporter/enregistrer le(s) fichier(s) texte, puis de réinitialiser les préférences.Voici un script pour ce faire.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
pathout = "c:\temp\";
ofid = "BigClass_csv";
// Save as text with comma delimiters
// Get user Export Preferences
xptPref = Get Preferences( Export Settings );
// Set desired Export Preferences
Preferences(
ExportSettings(
End Of Line( CRLF ),
End Of Field( Comma ), //optionally try: Tab|Space|Other("|")|Other("^") etc
Export Table Headers( 1 )
)
);
// Save as .txt
dt << Save( pathOut || ofid || ".txt" );
// Reset user Export Preferences
Eval( xptPref );
// xptPref; // works as well.
Close(dt,NoSave);
Rename File( pathout || ofid || ".txt", ofid || ".csv");.
J'espère que l'un d'entre eux fonctionnera pour vous.
