226888_es-ES

liliconcom

Iterar a través de las filas y seleccionar el script de filas coincidentes y luego promediar

Hola, 

 

Estoy tratando de escribir un script que use una columna para seleccionar celdas coincidentes allí y luego use esas filas seleccionadas para encontrar el promedio de los números en la columna al lado, pero no estoy muy seguro de cómo hacerlo. Aquí hay una tabla de ejemplo de lo que estoy trabajando (la última nube promedio es lo que necesito que haga un script):

Columna a juego:	Números:	Promedio de números agrupados
una	2	3
una	4 4	3
si	2	4 4
si	4 4	4 4
si	6 6	4 4
C	3	6 6
C	6 6	6 6
C	9 9	6 6
re	2	2
re	2	2

Re: iterar a través de las filas y seleccionar el script de filas coincidentes y luego promediar

Hay varias formas de abordar esto, pero la que encuentro más fácil es usar

     Tablas ==> Resumen

para hacer el resumen y luego fusionar los datos de resumen nuevamente en la tabla original.  Aquí hay un script simple que usa sus datos de ejemplo para hacer eso

Names Default To Here( 1 );

// Create an example data table
dt = New Table( "Example",
 Add Rows( 10 ),
 New Column( "Matching Column",
  Character,
  "Nominal",
  Set Values( {"a", "a", "b", "b", "b", "c", "c", "c", "d", "d"} )
 ),
 New Column( "Numbers",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [2, 4, 2, 4, 6, 3, 6, 9, 2, 2] )
 )
);

// Pause so one can see the original table
wait(5);

// Summarize the data
dtSum = dt << Summary(
 invisible,
 Group( :Matching Column ),
 Mean( :Numbers ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 ),
 output table name( "Means" )
);

// Adjust items in summary data to allow for proper merging
dtSum << delete columns( "N Rows" );
dtSum:Numbers << Set Name( "Average of grouped numbers" );

// Add the summary data to the original data table
dt << Update( With( dtSum ), Match Columns( :Matching Column = :Matching Column ) );

// Clean up the environment
Close( dtSum, nosave );

Re: iterar a través de las filas y seleccionar el script de filas coincidentes y luego promediar

No necesitas un script para esto. los Media de la columna () La función en el Editor de fórmulas calculará los medios mediante una columna de agrupación.

 

Adjunté una tabla de datos hecha del ejemplo que publicó para que pueda ver cómo se ve en JMP.

 

Re: iterar a través de las filas y seleccionar el script de filas coincidentes y luego promediar

Si muchas gracias que funcionó