nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

How to achieve automatic batch replacement with JSL?

lwx228

This table is generated dynamically by the JSL running process. How to use the JSL automatic implementation to replace the 0 value starting from column 2 of this table with a null value "" ?

JSL is required to be replaced with a list of column Numbers or dynamic names.

Either a column - by - column replacement or a one-time replacement.

Accepted answers

Mark_Bailey

I cannot test this script but it should work.

Names Default to Here( 1 );

// assume that data table is open
dt = Current Data Table();

For( c = 2, c <= N Cols( dt ), c++,
	target row = dt << Get Rows Where( Column( dt, c )[] == 0 );
	If( N Rows( target row ) > 0,
		For( r = 1, r <= N Rows( target row ), r++,
			Column( dt, c )[target row[r]] = .;
		);
	);
);

All comments

lwx228

Upload a data file, Ask the experts for help.Thank you very much!

lwx228

I was careless. I used the grammar of VBA directly and forgot to use "Empty()".

MichelleG

I don't know if this is the most computationally-efficient way of doing this -- in fact, I assume it's not. But if you need a quick brute-force solution, this has worked for me in the past: loop over the columns, then loop over the rows looking for the value you want to replace, setting the new value as you find it.

dt = current data table();
colnames = dt << Get Column Names(String);
for(c=2,c<=N Items(colnames),c++, // starting at 2 per your note
	For Each Row(
		If(column(dt,colnames[c])[]==0, // if you find a 0
			column(dt,colnames[c])[]=Empty() // make it empty
		)
	)
);

Mark_Bailey

I cannot test this script but it should work.

Names Default to Here( 1 );

// assume that data table is open
dt = Current Data Table();

For( c = 2, c <= N Cols( dt ), c++,
	target row = dt << Get Rows Where( Column( dt, c )[] == 0 );
	If( N Rows( target row ) > 0,
		For( r = 1, r <= N Rows( target row ), r++,
			Column( dt, c )[target row[r]] = .;
		);
	);
);

MichelleG

Nice, this cuts down on the number of rows to loop over, saving time on big tables. I was thinking there might be a way to use the Recode functionality on the table as a whole, but I see you've (@Mark_Bailey) already explained elsewhere that this is an interactive editor, not a JSL function.

Mark_Bailey

Such processing will be even easier and faster in JMP 15. You will be able assign the missing value to all the rows in one call.

Names Default to Here( 1 );

// assume that data table is open
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Wait( 1 );

// create 5 observations of zero
n = N Row( dt );
For( i = 1, i < 6, i++,
	r = Random Integer( 1, n );
	:weight[r] = 0;
	r = Random Integer( 1, n );
	:height[r] = 0;
);
Wait( 1 );

For( c = 4, c <= N Cols( dt ), c++,
	target row = dt << Get Rows Where( Column( dt, c )[] == 0 );
	If( N Rows( target row ) > 0,
		Column( dt, c )[target row] = .;
	);
);

lwx228

I'm really looking forward to using JMP 15.Thank you very much!

pmroz

The syntax:

For( c = 4, c <= N Cols( dt ), c++,
	target row = dt << Get Rows Where( Column( dt, c )[] == 0 );
	If( N Rows( target row ) > 0,
		Column( dt, c )[target row] = .;
	);
);

already works in JMP 14.