226101_ja-JP

liliconcom

逆予測の未知数の列全体を入力します

こんにちは、

 

線形近似から計算する100個の未知数があります。ここに示す「逆予測」の指示に従いました。

https://www.jmp.com/support/help/14/inverse-prediction-2.shtml#149268

 

それはうまくいきましたが、この方法を使用すると、一度に（手動で）入力できるのは8つの未知数だけです。これを行う別の方法はありますか（Prismにあるように）？または、それを実行できるスクリプトはありますか？プリズム法： https://www.graphpad.com/support/faq/prism-3-calculating-unknown-concentrations-using-a-standard-curve/

 

ありがとう！

メーガン

再：逆予測のための未知数の列全体を入力

スクリプトが最適なソリューションを提供すると思います。標準と未知のデータテーブルは同じデータテーブルですか、それとも個別のデータテーブルですか？さらに良いことに、標準と未知の両方を備えた典型的なデータセットの例を提供できますか？

再：逆予測のための未知数の列全体を入力

ハイマーク、

 

このメモにサンプルデータを添付しました。標準データと未知データは同じデータテーブルにあります。

この例では、2つのポイント10と150が重複する標準曲線があります。空白のままにしたUnknowns [ここではgDNA pg / uL]を補間したいと思います。 

 

メーガン

再：逆予測のための未知数の列全体を入力

このスクリプトは、各チップIDに対して個別に逆予測を実行します。

 

Names Default to Here( 1 );

dt = Current Data Table();

Column( 2 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );
Column( 3 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );

dt << New Column( "Lower 95%", "Numeric", "Continuous" )
   << New Column( "Upper 95%", "Numeric", "Continuous" );

Summarize( chip = By( :Chip ID ) );

n groups = N Items( chip );

For( c = 1, c <= n groups, c++,
 data = dt << Get Rows Where( :Chip ID == chip[c] );
 dt << Select Where( :Chip ID != chip[c] ) << Exclude;
 fls = dt << Fit Model(
  Y( :Median Electrode ),
  Effects( :Name( "gDNA pg/uL" ) ),
  Personality( "Standard Least Squares" ),
  Emphasis( "Minimal Report" ),
  Run
 );
 unknown = :Median Electrode[data[3]::data[N Row(data)-2]];
 Eval(
  Substitute(
   Expr(
    fls << Inverse Prediction(
     Term Value( Name( "gDNA pg/uL" )(.) ),
     Response( rrr )
    )
   ),
   Expr( rrr ),
   unknown
  )
 );
 inv pred report = Report( fls )["Inverse Prediction"];
 inv pred = inv pred report[NumberColBox(2)] << Get As Matrix;
 lower = inv pred report[NumberColBox(3)] << Get As Matrix;
 upper = inv pred report[NumberColBox(4)] << Get As Matrix;
 fls << Close Window;
 For( i = 1, i < N Row( data ) - 3, i++,
  Column( 2 )[data[i+2]] = inv pred[i];
  Column( 4 )[data[i+2]] = lower[i];
  Column( 5 )[data[i+2]] = upper[i];
 );
 dt << Exclude << Clear Select;
);

 

注：最後に空の行を削除しない限り、失敗します。標準の1つに、既知の濃度の値10がありません。

再：逆予測のための未知数の列全体を入力これは機能し、アプリケーションの素晴らしいスタートです！どうもありがとうございます！！次に、チップではなく、チップ全体のすべての標準曲線値で逆予測を行う方法を理解する必要があります。（JMPの学習を開始しました。）再：逆予測のための未知数の列全体を入力

このスクリプトの素晴らしさをもう一度言いたかっただけです。新しいJMPユーザーとして、私は本当にあなたの努力に感謝しています。