226101_it-IT

liliconcom

Inserisci l'intera colonna di Unknowns per Inverse Prediction

Ciao,

 

Ho 100 sconosciuti da calcolare da un adattamento lineare. Ho seguito le istruzioni per "Inverse Prediction" mostrate qui:

https://www.jmp.com/support/help/14/inverse-prediction-2.shtml#149268

 

Funzionava bene, ma usando questo metodo, posso solo inserire (manualmente) 8 sconosciuti alla volta. C'è un altro modo per farlo (come nel Prisma)? O c'è una sceneggiatura che può farlo? Metodo del prisma: https://www.graphpad.com/support/faq/prism-3-calculating-unknown-concentrations-using-a-standard-curve/

 

Grazie!

Meghan

Ri: Immettere l'intera colonna di Unknowns per Inverse Prediction

Penso che uno script fornirebbe la soluzione migliore. Gli standard e gli incogniti sono nella stessa tabella di dati o tabelle di dati separate? Meglio ancora, puoi fornire un esempio di un set di dati tipico con standard e incognite?

Ri: Immettere l'intera colonna di Unknowns per Inverse Prediction

Ciao Mark,

 

Ho allegato alcuni dati di esempio a questa nota: standard e incognite si trovano nella stessa tabella di dati.

In questo esempio, ho una curva standard con due punti 10 e 150 in duplicato. Voglio interpolare gli sconosciuti [qui gDNA pg / uL] che ho lasciato in bianco. 

 

Meghan

Ri: Immettere l'intera colonna di Unknowns per Inverse Prediction

Questo script eseguirà la previsione inversa per ciascun ID chip separatamente.

 

Names Default to Here( 1 );

dt = Current Data Table();

Column( 2 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );
Column( 3 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );

dt << New Column( "Lower 95%", "Numeric", "Continuous" )
   << New Column( "Upper 95%", "Numeric", "Continuous" );

Summarize( chip = By( :Chip ID ) );

n groups = N Items( chip );

For( c = 1, c <= n groups, c++,
 data = dt << Get Rows Where( :Chip ID == chip[c] );
 dt << Select Where( :Chip ID != chip[c] ) << Exclude;
 fls = dt << Fit Model(
  Y( :Median Electrode ),
  Effects( :Name( "gDNA pg/uL" ) ),
  Personality( "Standard Least Squares" ),
  Emphasis( "Minimal Report" ),
  Run
 );
 unknown = :Median Electrode[data[3]::data[N Row(data)-2]];
 Eval(
  Substitute(
   Expr(
    fls << Inverse Prediction(
     Term Value( Name( "gDNA pg/uL" )(.) ),
     Response( rrr )
    )
   ),
   Expr( rrr ),
   unknown
  )
 );
 inv pred report = Report( fls )["Inverse Prediction"];
 inv pred = inv pred report[NumberColBox(2)] << Get As Matrix;
 lower = inv pred report[NumberColBox(3)] << Get As Matrix;
 upper = inv pred report[NumberColBox(4)] << Get As Matrix;
 fls << Close Window;
 For( i = 1, i < N Row( data ) - 3, i++,
  Column( 2 )[data[i+2]] = inv pred[i];
  Column( 4 )[data[i+2]] = lower[i];
  Column( 5 )[data[i+2]] = upper[i];
 );
 dt << Exclude << Clear Select;
);

 

Nota: fallirà se non rimuovi le righe vuote alla fine. A uno degli standard manca il valore 10 per la concentrazione nota.

Ri: Immettere l'intera colonna di Unknowns per Inverse PredictionFunziona ed è un ottimo inizio per la nostra applicazione! Grazie mille!! Successivamente, dobbiamo capire come eseguire la previsione inversa non tramite Chip, ma in base a tutti i valori della curva standard attraverso i chip. (Abbiamo appena iniziato a studiare JMP.)Ri: Immettere l'intera colonna di Unknowns per Inverse Prediction

Volevo solo ribadire quanto sia fantastico questo script. Come nuovo utente JMP, apprezzo molto il tuo impegno.