226101_ko-KR

liliconcom

역 예측을 위해 미지수 열 전체 입력

여보세요,

 

선형 피팅에서 계산할 100 개의 알 수 없음이 있습니다. 여기에 표시된 "역 예측"에 대한 지침을 따랐습니다.

https://www.jmp.com/support/help/14/inverse-prediction-2.shtml#149268

 

잘 작동했지만이 방법을 사용하면 한 번에 8 개의 알 수 없음을 수동으로 입력 할 수 있습니다. 프리즘에있는 것처럼 다른 방법이 있습니까? 아니면 그것을 할 수있는 스크립트가 있습니까? 프리즘 방법 : https://www.graphpad.com/support/faq/prism-3-calculating-unknown-concentrations-using-a-standard-curve/

 

감사!

메간

다시 : 역 예측을 위해 미지수 열 전체 입력

스크립트가 최상의 솔루션을 제공 할 것이라고 생각합니다. 동일한 데이터 테이블 또는 별도의 데이터 테이블에 표준 및 미지수가 있습니까? 더 나은 방법은 표준과 미지의 표준 데이터 세트의 예를 제공 할 수 있습니까?

다시 : 역 예측을 위해 미지수 열 전체 입력

안녕 마크,

 

이 노트에 일부 샘플 데이터를 첨부했습니다. 표준 데이터와 미지수는 동일한 데이터 테이블에 있습니다.

이 예에서는 두 점 10과 150이 중복 된 표준 곡선이 있습니다. 비워 둔 Unknowns [여기서는 gDNA pg / uL]를 보간하고 싶습니다. 

 

메간

다시 : 역 예측을 위해 미지수 열 전체 입력

이 스크립트는 각 칩 ID에 대해 개별적으로 역 예측을 수행합니다.

 

Names Default to Here( 1 );

dt = Current Data Table();

Column( 2 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );
Column( 3 ) << Data Type( "Numeric" ) << Modeling Type( "Continuous" );

dt << New Column( "Lower 95%", "Numeric", "Continuous" )
   << New Column( "Upper 95%", "Numeric", "Continuous" );

Summarize( chip = By( :Chip ID ) );

n groups = N Items( chip );

For( c = 1, c <= n groups, c++,
 data = dt << Get Rows Where( :Chip ID == chip[c] );
 dt << Select Where( :Chip ID != chip[c] ) << Exclude;
 fls = dt << Fit Model(
  Y( :Median Electrode ),
  Effects( :Name( "gDNA pg/uL" ) ),
  Personality( "Standard Least Squares" ),
  Emphasis( "Minimal Report" ),
  Run
 );
 unknown = :Median Electrode[data[3]::data[N Row(data)-2]];
 Eval(
  Substitute(
   Expr(
    fls << Inverse Prediction(
     Term Value( Name( "gDNA pg/uL" )(.) ),
     Response( rrr )
    )
   ),
   Expr( rrr ),
   unknown
  )
 );
 inv pred report = Report( fls )["Inverse Prediction"];
 inv pred = inv pred report[NumberColBox(2)] << Get As Matrix;
 lower = inv pred report[NumberColBox(3)] << Get As Matrix;
 upper = inv pred report[NumberColBox(4)] << Get As Matrix;
 fls << Close Window;
 For( i = 1, i < N Row( data ) - 3, i++,
  Column( 2 )[data[i+2]] = inv pred[i];
  Column( 4 )[data[i+2]] = lower[i];
  Column( 5 )[data[i+2]] = upper[i];
 );
 dt << Exclude << Clear Select;
);

 

참고 : 끝에 빈 행을 제거하지 않으면 실패합니다. 표준 중 하나에 알려진 농도의 값 10이 없습니다.

다시 : 역 예측을 위해 미지수 열 전체 입력이것은 작동하며 응용 프로그램을 시작하기에 좋은 시작입니다! 정말 고맙습니다!! 다음으로 우리는 칩이 아니라 칩 전체의 모든 표준 곡선 값으로 역 예측을 수행하는 방법을 알아낼 필요가 있습니다. (JMP를 배우기 시작했습니다.)다시 : 역 예측을 위해 미지수 열 전체 입력

이 스크립트가 얼마나 멋진 지 반복하고 싶었습니다. 새로운 JMP 사용자로서 귀하의 노력을 진심으로 감사드립니다.