Externally Studentized Residuals

MikeD_Anderson

Hi, all! 

 

I have a customer that's would like to access the externally studentized residuals used for the studentized residuals plot in Least Squares Regression.  Anybody have a way to calculate that outside of the platform or know how to get at those values?

 

Best,

 

M

ian_jmp

I didn't look at any of the numbers, but you can always get the values directly from the marker seg in the report:

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Fit Model
fm = dt << Fit Model(
					Y( :height ),
					Effects( :weight ),
					Personality( "Standard Least Squares" ),
					Emphasis( "Effect Leverage" ),
					Run(
						:height << {Summary of Fit( 0 ), Analysis of Variance( 0 ),
						Parameter Estimates( 0 ), Effect Tests( 0 ), Effect Details( 0 ),
						Lack of Fit( 0 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ),
						Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 1 ),
						Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
						Box Cox Y Transformation( 0 )}
					),
					SendToReport(
						Dispatch(
							{"Response height", "Whole Model"},
							"Regression Plot",
							OutlineBox,
							{Close( 1 )}
						),
						Dispatch(
							{"Response height", "Whole Model"},
							"Actual by Predicted Plot",
							OutlineBox,
							{Close( 1 )}
						)
					)
				);

// Get values directly from the marker seg . . .				
fmRep = Report(fm);
frame = fmRep[FrameBox(4)];
mySeg = (frame << Find Seg( Marker Seg( 1 ) ));
xVals = mySeg << Get X Values;
yVals = mySeg << Get Y Values;
dt2 = asTable(xVals||yVals, << columnNames({"Row Number", "Studentized Residual"}));
dt2 << setName("Residuals");