222080_fr-FR

liliconcom

Zone de tabulation non renseignée correctement

Salut à tous,

 

J'essaie de créer une fenêtre qui a plusieurs onglets "Plist" et affiche chaque graphique par étiquette. Le script fonctionne bien mais ne montre pas les lignes de référence (qui référencent une colonne) lors de l’exécution du script. Existe-t-il une solution de contournement pour les tracés bivariés d'afficher ces lignes de référence en fonction de leur valeur de colonne? Vous trouverez ci-dessous le script que j'ai déjà exécuté avec succès, mais ne fonctionne plus. 

 

Merci!

 

 

Plist = {"Prod1", "Prod2", "Prod3", "Prod4"};
nw = New Window( "test", tb = Tab Box() );
For( y = 1, y <= N Items( Plist ), y++,
 dtflag << Select Where( :product == Plist[y] );
 Try( TempSubDT = dtflag << subset( Selected Rows, invisible ) );
 tb << Append(
  Char( Plist[y] ),
  V List Box(
   TempSubDT << Bivariate(
    SendToByGroup( Bygroup Default ),
    Y( :data ),
    X( :txn_time ),
    Automatic Recalc( 1 ),
    Fit Spline( 1e+18, {Line Color( {212, 73, 88} )}, Report( 0 ) ),
    By( :LABEL ),
    SendToReport(
     Dispatch( 
      {}, "1", ScaleBox, {Interval( "Day" ), Inc( 2 ), Minor Ticks( 0 ), Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Min( :LSL - :TGT* 0.1 ), Max( :USL + :TGT* 0.1 ), Add Ref Line( :USL, "Dashed", "Red", "USL", 2 ),
      Add Ref Line( :LSL, "Dashed", "Red", "LSL", 2 ), Add Ref Line( :UCL, "Dashed", "Green", "UCL", 2 ),
      Add Ref Line( :LCL, "Dashed", "Green", "LCL", 2 ), Add Ref Line( :TGT, "Solid", "Black", "Target", 2 )}
     ),
     Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 650, 300 )} )
    )
   )
  )
 );
);

Re: boîte à onglet ne pas remplir correctement

La valeur de la ligne de référence doit pointer vers une valeur unique plutôt que vers une colonne entière de valeurs. Par conséquent, votre ligne Ajouter une référence doit ressembler à quelque chose comme:

Add Ref Line( :USL[1], "Dashed", "Red", "USL", 2 ),
Add Ref Line( :LSL[1], "Dashed", "Red", "LSL", 2 ),
Add Ref Line( :UCL[1], "Dashed", "Green", "UCL", 2 ),
Add Ref Line( :LCL[1], "Dashed", "Green", "LCL", 2 ),
Add Ref Line( :TGT[1], "Solid", "Black", "Target", 2 )

Re: boîte à onglet ne pas remplir correctement

Ah cela a fonctionné parfaitement! Merci Nelson!