222080_it-IT

liliconcom

Casella di tabulazione non popolata correttamente

Ciao a tutti,

 

Sto cercando di creare una finestra che ha più schede "Plist" e visualizza ogni grafico per etichetta. Lo script funziona correttamente ma non mostra le linee di riferimento (che fanno riferimento a una colonna) quando viene eseguito lo script. Esiste una soluzione alternativa per i grafici bivariati per visualizzare queste linee di riferimento in base al loro valore di colonna ??? Di seguito è riportato il mio script che ho eseguito con successo in precedenza, ma ha smesso di funzionare. 

 

Grazie!

 

 

Plist = {"Prod1", "Prod2", "Prod3", "Prod4"};
nw = New Window( "test", tb = Tab Box() );
For( y = 1, y <= N Items( Plist ), y++,
 dtflag << Select Where( :product == Plist[y] );
 Try( TempSubDT = dtflag << subset( Selected Rows, invisible ) );
 tb << Append(
  Char( Plist[y] ),
  V List Box(
   TempSubDT << Bivariate(
    SendToByGroup( Bygroup Default ),
    Y( :data ),
    X( :txn_time ),
    Automatic Recalc( 1 ),
    Fit Spline( 1e+18, {Line Color( {212, 73, 88} )}, Report( 0 ) ),
    By( :LABEL ),
    SendToReport(
     Dispatch( 
      {}, "1", ScaleBox, {Interval( "Day" ), Inc( 2 ), Minor Ticks( 0 ), Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Min( :LSL - :TGT* 0.1 ), Max( :USL + :TGT* 0.1 ), Add Ref Line( :USL, "Dashed", "Red", "USL", 2 ),
      Add Ref Line( :LSL, "Dashed", "Red", "LSL", 2 ), Add Ref Line( :UCL, "Dashed", "Green", "UCL", 2 ),
      Add Ref Line( :LCL, "Dashed", "Green", "LCL", 2 ), Add Ref Line( :TGT, "Solid", "Black", "Target", 2 )}
     ),
     Dispatch( {}, "Bivar Plot", FrameBox, {Frame Size( 650, 300 )} )
    )
   )
  )
 );
);

Ri: Casella di tabulazione non popolata correttamente

Il valore della linea di riferimento deve puntare a un singolo valore, anziché a un'intera colonna di valori, pertanto, Aggiungi linea di riferimento deve essere simile a:

Add Ref Line( :USL[1], "Dashed", "Red", "USL", 2 ),
Add Ref Line( :LSL[1], "Dashed", "Red", "LSL", 2 ),
Add Ref Line( :UCL[1], "Dashed", "Green", "UCL", 2 ),
Add Ref Line( :LCL[1], "Dashed", "Green", "LCL", 2 ),
Add Ref Line( :TGT[1], "Solid", "Black", "Target", 2 )

Ri: Casella di tabulazione non popolata correttamente

Ah questo ha funzionato perfettamente! Grazie Nelson!