218083_it-IT

liliconcom

come aggiornare il valore della linea in bivariato

Ciao a tutti,

Provo a scrivere uno script in JSL, che crea una nuova finestra che contiene bivariata e cambia il valore della linea nell'asse y da un valore di 5 a un valore di 40 premendo il pulsante OK.
Cioè, la bivarite viene visualizzata in una nuova finestra con una riga di circa 5, e dopo aver premuto il pulsante "OK", la riga cambia da 5 a 40, nella stessa finestra !!
Aggiungo il codice che ho scritto, fa apparire la nuova finestra e crea il bivariato con la riga circa 5 ma non posso cambiare il valore della riga facendo clic.

Grazie a tutti gli aiutanti!

 

 

TEST = open("C:\Users\shimi\Desktop\WP\TESTS\test refrsh.jmp","private");
TEST_V = 5;
New Window( "Inval example",
Button Box( "OK",
TEST_V=40;
g1 << inval; /* tell the oval to redraw */
g1 << update;
x = Tick Seconds();
While( Tick Seconds() - x < .5, 0 /* delay without wait(.5) */ );
),

g1 =TEST << Bivariate(
 Y( :nean ),
 X( :time ),
 SendToReport(
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Add Ref Line( TEST_V, "Solid", "Purple", "TEST", 2 )}
  )
 )
)
);

 

Ri: come aggiornare il valore della linea in bivariato

L'uso della direttiva Send To Report () è un modo per JMP di salvare uno script che include tutte le modifiche apportate. Non è generalmente destinato allo scripting. Un modo migliore è utilizzare un riferimento all'oggetto (casella di visualizzazione) per inviare un messaggio specifico. Questo esempio illustra un modo per gestire le linee di riferimento mediante uno script.

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

biv = dt << Bivariate(
 Y( :weight ),
 X( :height )
);

biv rep = biv << Report;

biv rep[AxisBox( 2 )] << Add Ref Line( 55 );

Wait( 2 );

biv rep[AxisBox( 2 )] << Remove Ref Line( 55 );
biv rep[AxisBox( 2 )] << Add Ref Line( 65 );

Ri: come aggiornare il valore della linea in bivariato

Hey,
Non so perché, ma quando provo a prendere il codice che hai scritto nel mio codice il mio codice non funziona.
Potresti avere un'altra idea di come farlo?

Ri: come aggiornare il valore della linea in bivariato

Non so nemmeno perché il tuo codice non funzioni. Non so come hai incorporato la mia soluzione nel tuo codice.

 

Non conosco un altro modo. Anche se esiste un altro modo, potresti provare a eseguire il debug dello script e risolverlo invece di cercare un altro modo.

Ri: come aggiornare il valore della linea in bivariato

Questa è la parte rilevante del codice che ho scritto con la tua soluzione,
Mi piacerebbe vedere se vedi un problema che ti viene in mente.

 

 Layer_Charts = vlistbox(Outline Box(Layer),biv = dt_LTK__Sum << 
 Bivariate(
  Y( :Name( "Mean(RAW_VALUE)" ) ),
  X( :lot_data_collect_date ),
 SendToReport(
  Dispatch( {}, "1", ScaleBox, {Rotated Labels( "Angled" )} ),
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Min( Eval(CL - Dl*(1+ig)) ), Max( Eval(CL + Du*(1+ig))), Inc( Eval((UCL-LCL)/3 )),
   Add Ref Line( Eval(CL), Solid, "Red", "CL", 1 ),
   Add Ref Line( Eval(UCL), Dotted, "Red", "UCL", 1 ),
   Add Ref Line( Eval(LCL), Dotted, "Red", "LCL", 1 )}
  ),
  Dispatch(
   {},
   "Bivar Plot",
   FrameBox,
   {Row Legend(
    ENTITY,
    Color( 1 ),
    Color Theme( "JMP Default" ),
    Marker( 1 ),
    Marker Theme( "Standard" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 )

);
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ), // a little vertical space
H List Box( Text Box( "enter NEW CL: " ), Spacer Box( size( 3, 1 ) ), theBinNumber = Number Edit Box() ,Spacer Box( size( 15, 1 ) )),
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ),
biv rep = biv << Report;

 Button Box( "OK",
  NEW_CL = theBinNumber << get;
  NEW_UCL =  NEW_CL + Du;
  NEW_LCL= NEW_CL -Dl;
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_CL), Dotted, "Purple",( "NEW CL = [" || char(NEW_CL) || "]  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_UCL), Dotted, "Purple", ( "NEW UCL = " || char(NEW_UCL) || "  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_LCL), Dotted, "Purple", ( "NEW LCL = " || char(NEW_LCL) || "  " ), 2);
  biv rep[AxisBox( 1 )] << Add Ref Line(  informat(date_RR << get text;); ;, "Dashed", "Green", "RR", 2);

Ri: come aggiornare il valore della linea in bivariato

Ho alcune schede, ogni scheda che ho bivariato.
Potete per favore dirmi che devo cambiare se ho delle schede con Bivariate in ognuna di esse?
Potete inviarmi una soluzione che risolva il problema con alcune schede?

Ri: come aggiornare il valore della linea in bivariato

Ecco un esempio molto semplice, che crea 2 schede, quindi quando viene premuto un pulsante (), viene generata una linea di riferimento per la scheda in cui è stato premuto il pulsante

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert(
      i,
      "Graph " || Char( i ),
      Tab Page Box(
       __biv__ = bivariate( x( :height ), y( :weight ) ),
       __bb__ = Button Box( "Push Me",
        __biv__rep__ << Add Ref Line(
         100,
         Dotted,
         "Purple",
         "100",
         2
        )
       )
      )
     )
    ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);

Ri: come aggiornare il valore della linea in bivariato

Non funziona ...

Ri: come aggiornare il valore della linea in bivariato

Quale versione di JMP stai usando? Il mio script funziona in JMP 13 e 14, ma non funziona in versioni precedenti.

Ri: come aggiornare il valore della linea in bivariatoJmp12
Ri: come aggiornare il valore della linea in bivariato

Ecco una versione che funziona per JMP 12, 13 e 14.  Le nuove opzioni incorporate in JMP 13 dovevano essere rielaborate per funzionare nelle versioni precedenti.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert( i, "Graph " || Char( i ), __vlb__ = V List Box() );
     __vlb__ << append( __biv__ = bivariate( x( :height ), y( :weight ) ) );
     __vlb__ << append(
      __bb__ = Button Box( "Push Me",
       __biv__rep__ << Add Ref Line( 100, Dotted, "Purple", "100", 2 )
      )
     );
    ),
   Expr( __vlb__ ), Parse( "Vlb" || Char( i ) ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);