218083_zh-TW

liliconcom

如何更新雙變量線的值

大家好，

我嘗試在JSL中編寫一個腳本，它創建一個包含雙變量的新窗口，並通過按下OK按鈕將y軸中的行值從值5更改為值40。
也就是說，bivarite顯示在一個大約5行的新窗口中，按下“OK”按鈕後，行在同一個窗口中從5變為40！
我添加了我編寫的代碼，它會調出新窗口並使用大約5行創建雙變量但不能通過單擊來更改行的值。

感謝所有的幫助！

 

 

TEST = open("C:\Users\shimi\Desktop\WP\TESTS\test refrsh.jmp","private");
TEST_V = 5;
New Window( "Inval example",
Button Box( "OK",
TEST_V=40;
g1 << inval; /* tell the oval to redraw */
g1 << update;
x = Tick Seconds();
While( Tick Seconds() - x < .5, 0 /* delay without wait(.5) */ );
),

g1 =TEST << Bivariate(
 Y( :nean ),
 X( :time ),
 SendToReport(
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Add Ref Line( TEST_V, "Solid", "Purple", "TEST", 2 )}
  )
 )
)
);

 

Re：如何更新雙變量線的值

使用Send To Report（）指令是JMP保存包含您所做的任何修改的腳本的一種方法。它通常不用於編寫腳本。更好的方法是使用對象（顯示框）的引用來發送特定的消息。此示例說明了通過腳本管理參考線的一種方法。

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

biv = dt << Bivariate(
 Y( :weight ),
 X( :height )
);

biv rep = biv << Report;

biv rep[AxisBox( 2 )] << Add Ref Line( 55 );

Wait( 2 );

biv rep[AxisBox( 2 )] << Remove Ref Line( 55 );
biv rep[AxisBox( 2 )] << Add Ref Line( 65 );

Re：如何更新雙變量線的值

嘿，
我不知道為什麼，但是當我嘗試將您編寫的代碼寫入我的代碼時，我的代碼不起作用。
你可能有另一個想法怎麼做？

Re：如何更新雙變量線的值

我不知道為什麼你的代碼也不起作用。我不知道你是如何將我的解決方案整合到你的代碼中的。

 

我不知道另一種方式。即使有其他方法，您也可以嘗試調試腳本並修復它，而不是尋找其他方法。

Re：如何更新雙變量線的值

這是我用您的解決方案編寫的代碼的相關部分，
我很想知道你是否看到一個突然出現問題的問題。

 

 Layer_Charts = vlistbox(Outline Box(Layer),biv = dt_LTK__Sum << 
 Bivariate(
  Y( :Name( "Mean(RAW_VALUE)" ) ),
  X( :lot_data_collect_date ),
 SendToReport(
  Dispatch( {}, "1", ScaleBox, {Rotated Labels( "Angled" )} ),
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Min( Eval(CL - Dl*(1+ig)) ), Max( Eval(CL + Du*(1+ig))), Inc( Eval((UCL-LCL)/3 )),
   Add Ref Line( Eval(CL), Solid, "Red", "CL", 1 ),
   Add Ref Line( Eval(UCL), Dotted, "Red", "UCL", 1 ),
   Add Ref Line( Eval(LCL), Dotted, "Red", "LCL", 1 )}
  ),
  Dispatch(
   {},
   "Bivar Plot",
   FrameBox,
   {Row Legend(
    ENTITY,
    Color( 1 ),
    Color Theme( "JMP Default" ),
    Marker( 1 ),
    Marker Theme( "Standard" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 )

);
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ), // a little vertical space
H List Box( Text Box( "enter NEW CL: " ), Spacer Box( size( 3, 1 ) ), theBinNumber = Number Edit Box() ,Spacer Box( size( 15, 1 ) )),
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ),
biv rep = biv << Report;

 Button Box( "OK",
  NEW_CL = theBinNumber << get;
  NEW_UCL =  NEW_CL + Du;
  NEW_LCL= NEW_CL -Dl;
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_CL), Dotted, "Purple",( "NEW CL = [" || char(NEW_CL) || "]  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_UCL), Dotted, "Purple", ( "NEW UCL = " || char(NEW_UCL) || "  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_LCL), Dotted, "Purple", ( "NEW LCL = " || char(NEW_LCL) || "  " ), 2);
  biv rep[AxisBox( 1 )] << Add Ref Line(  informat(date_RR << get text;); ;, "Dashed", "Green", "RR", 2);

Re：如何更新雙變量線的值

我有幾個標籤，每個標籤我都有雙變量。
你可以告訴我，如果我在每個人都有一些雙變量標籤，我需要改變嗎？
你能給我一個解決問題的解決方案嗎？

Re：如何更新雙變量線的值

這是一個非常簡單的示例，它創建了2個選項卡，然後當按下一個按鈕框（）時，它會為按鈕按下該選項卡生成一個參考線

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert(
      i,
      "Graph " || Char( i ),
      Tab Page Box(
       __biv__ = bivariate( x( :height ), y( :weight ) ),
       __bb__ = Button Box( "Push Me",
        __biv__rep__ << Add Ref Line(
         100,
         Dotted,
         "Purple",
         "100",
         2
        )
       )
      )
     )
    ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);

Re：如何更新雙變量線的值

它不起作用......

Re：如何更新雙變量線的值

您使用的是什麼版本的JMP？我的腳本適用於JMP 13和14，但在早於此版本的版本中不起作用。

Re：如何更新雙變量線的值Jmp12
回复：如何更新雙變量行的值

這是適用於JMP 12、13和14的版本。  必須修改JMP 13中包含的新選項，以使其在較早版本中工作。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert( i, "Graph " || Char( i ), __vlb__ = V List Box() );
     __vlb__ << append( __biv__ = bivariate( x( :height ), y( :weight ) ) );
     __vlb__ << append(
      __bb__ = Button Box( "Push Me",
       __biv__rep__ << Add Ref Line( 100, Dotted, "Purple", "100", 2 )
      )
     );
    ),
   Expr( __vlb__ ), Parse( "Vlb" || Char( i ) ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);