218083_es-ES

liliconcom

Como actualizar el valor de linea en bivariable.

Hola a todos,

Intento escribir un script en JSL, que crea una nueva ventana que contiene bivariada y cambia el valor de la línea en el eje y de un valor de 5 a un valor de 40 presionando el botón OK.
Es decir, la bivarita se muestra en una nueva ventana con una línea de aproximadamente 5, y después de presionar el botón "OK", la línea cambia de 5 a 40, en la misma ventana!
Agrego el código que escribí, aparece la nueva ventana y crea el bivariado con la línea de aproximadamente 5, pero no puede cambiar el valor de la línea haciendo clic.

Gracias a todos los ayudantes!

 

 

TEST = open("C:\Users\shimi\Desktop\WP\TESTS\test refrsh.jmp","private");
TEST_V = 5;
New Window( "Inval example",
Button Box( "OK",
TEST_V=40;
g1 << inval; /* tell the oval to redraw */
g1 << update;
x = Tick Seconds();
While( Tick Seconds() - x < .5, 0 /* delay without wait(.5) */ );
),

g1 =TEST << Bivariate(
 Y( :nean ),
 X( :time ),
 SendToReport(
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Add Ref Line( TEST_V, "Solid", "Purple", "TEST", 2 )}
  )
 )
)
);

 

Re: como actualizar el valor de linea en bivariada

El uso de la directiva Enviar a informe () es una forma en que JMP puede guardar una secuencia de comandos que incluye cualquier modificación que haya realizado. En general, no está destinado a secuencias de comandos. Una mejor manera es usar una referencia al objeto (cuadro de visualización) para enviar un mensaje específico. Este ejemplo ilustra una forma de administrar líneas de referencia mediante un script.

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

biv = dt << Bivariate(
 Y( :weight ),
 X( :height )
);

biv rep = biv << Report;

biv rep[AxisBox( 2 )] << Add Ref Line( 55 );

Wait( 2 );

biv rep[AxisBox( 2 )] << Remove Ref Line( 55 );
biv rep[AxisBox( 2 )] << Add Ref Line( 65 );

Re: como actualizar el valor de linea en bivariada

Oye,
No sé por qué, pero cuando intento tomar el código que escribiste en mi código, mi código no funciona.
Usted puede tener otra idea de cómo hacerlo?

Re: como actualizar el valor de linea en bivariada

Tampoco sé por qué tu código tampoco funciona. No sé cómo incorporaste mi solución a tu código.

 

No sé de otra manera. Incluso si hay otra forma, puede intentar depurar su script y corregirlo en lugar de buscar otra forma.

Re: como actualizar el valor de linea en bivariada

Esta es la parte relevante del código que escribí con su solución,
Me encantaría ver si ves un problema que aparece en tu ojo.

 

 Layer_Charts = vlistbox(Outline Box(Layer),biv = dt_LTK__Sum << 
 Bivariate(
  Y( :Name( "Mean(RAW_VALUE)" ) ),
  X( :lot_data_collect_date ),
 SendToReport(
  Dispatch( {}, "1", ScaleBox, {Rotated Labels( "Angled" )} ),
  Dispatch(
   {},
   "2",
   ScaleBox,
   {Min( Eval(CL - Dl*(1+ig)) ), Max( Eval(CL + Du*(1+ig))), Inc( Eval((UCL-LCL)/3 )),
   Add Ref Line( Eval(CL), Solid, "Red", "CL", 1 ),
   Add Ref Line( Eval(UCL), Dotted, "Red", "UCL", 1 ),
   Add Ref Line( Eval(LCL), Dotted, "Red", "LCL", 1 )}
  ),
  Dispatch(
   {},
   "Bivar Plot",
   FrameBox,
   {Row Legend(
    ENTITY,
    Color( 1 ),
    Color Theme( "JMP Default" ),
    Marker( 1 ),
    Marker Theme( "Standard" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 )

);
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ), // a little vertical space
H List Box( Text Box( "enter NEW CL: " ), Spacer Box( size( 3, 1 ) ), theBinNumber = Number Edit Box() ,Spacer Box( size( 15, 1 ) )),
Spacer Box( size( 1, 10 ) ), // a little vertical space
Spacer Box( size( 1, 10 ) ),
biv rep = biv << Report;

 Button Box( "OK",
  NEW_CL = theBinNumber << get;
  NEW_UCL =  NEW_CL + Du;
  NEW_LCL= NEW_CL -Dl;
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_CL), Dotted, "Purple",( "NEW CL = [" || char(NEW_CL) || "]  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_UCL), Dotted, "Purple", ( "NEW UCL = " || char(NEW_UCL) || "  " ), 2);
  biv rep[AxisBox( 2 )] << Add Ref Line( Eval(NEW_LCL), Dotted, "Purple", ( "NEW LCL = " || char(NEW_LCL) || "  " ), 2);
  biv rep[AxisBox( 1 )] << Add Ref Line(  informat(date_RR << get text;); ;, "Dashed", "Green", "RR", 2);

Re: como actualizar el valor de linea en bivariada

Tengo algunas pestañas, todas las pestañas que tengo Bivariate.
¿Puede decirme si necesito cambiar uh si tengo algunas pestañas con Bivariate en cada una de ellas?
¿Me puede enviar una solución que responda al problema con algunas pestañas?

Re: como actualizar el valor de linea en bivariada

Aquí hay un ejemplo muy simple, que crea 2 pestañas, y luego, cuando se presiona un cuadro de botón (), genera una línea de referencia para la pestaña cuando se presionó el botón

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert(
      i,
      "Graph " || Char( i ),
      Tab Page Box(
       __biv__ = bivariate( x( :height ), y( :weight ) ),
       __bb__ = Button Box( "Push Me",
        __biv__rep__ << Add Ref Line(
         100,
         Dotted,
         "Purple",
         "100",
         2
        )
       )
      )
     )
    ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);

Re: como actualizar el valor de linea en bivariada

No funciona ...

Re: como actualizar el valor de linea en bivariada

¿Qué versión de JMP estás usando? Mi script funciona en JMP 13 y 14, pero no funciona en versiones anteriores.

Re: como actualizar el valor de linea en bivariadaJmp12
Re: cómo actualizar el valor de la línea en bivariado

Aquí hay una versión que funciona para JMP 12, 13 y 14.  Las nuevas opciones incorporadas en JMP 13 tuvieron que ser modificadas para que funcionara en versiones anteriores.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "Example", tab = Tab Box() );

For( i = 1, i <= 2, i++,
 Eval(
  Substitute(
    Expr(
     tab << Insert( i, "Graph " || Char( i ), __vlb__ = V List Box() );
     __vlb__ << append( __biv__ = bivariate( x( :height ), y( :weight ) ) );
     __vlb__ << append(
      __bb__ = Button Box( "Push Me",
       __biv__rep__ << Add Ref Line( 100, Dotted, "Purple", "100", 2 )
      )
     );
    ),
   Expr( __vlb__ ), Parse( "Vlb" || Char( i ) ),
   Expr( __biv__ ), Parse( "Biv" || Char( i ) ),
   Expr( __bb__ ), Parse( "bb" || Char( i ) ),
   Expr( __biv__rep__ ), Parse( "report(biv" || Char( i ) || ")[axisbox(1)]" )
  )
 )
);