217471_zh-CN

liliconcom

Re：通过JSL将增强数据点添加到现有数据表的末尾

1. 您的JSL中有一个引用到dt2数据表。

   PredictedResidual = dt2 << Neural(

   我认为那应该是“dt”
2. Add Rows（）函数需要指定一个数值，表示要添加的行数。  您的引用没有任何值，因此它不会添加任何行

   dt << add rows();

通过JSL将增强数据点添加到现有数据表的末尾

我目前有一个生成随机X列的脚本，根据X计算Y列，生成预测Y列，残差列（预测Y - Y）和预测Y列。从那里，我的代码选择残差低于3的行并删除它们。

 

我想再添加更多行的增强数据点，并再次进行循环，以减少残差。以下是我的代码：

 

 

// 1. Creates X1 column, and corresponding Y1 and Ystat columns
Close All( Data Tables, NoSave );
dt = New Table( "SampleRun 3",
 Add Rows( 100 ),
 New Script(
  "Ystat vs. X1",
  Graph Builder(
   Variables( X( :X1 ), Y( :Ystat ) ),
   Elements( Points( X, Y, Legend( 5 ) ) )
  )
 ),
 New Column( "X1", 

  Formula( Random Integer( 50 ) )
 ),
 New Column( "Y1", 

  Formula( If( :X1 < 25, 2 * :X1, 25 <= :X1 <= 30, 3 * :X1, 4 * :X1 ) )
 ),
 New Column( "Ystat", 

  Formula( :Y1 )
 )

);
// 2. Creates predicted Ystat column, saves formulas into same data table (first iteration)
PredictedYstat = dt << Neural(
 Y( :Ystat ),
 X( :X1 ),
 Informative Missing( 0 ),
 Validation Method( "Holdback", 0.3333 ),
 Fit( NTanH( 3 ) )
);
PredictedYStat << Save Profile Formulas;

// 3. Adds residual column
dt << New Column( "Residual 1", Formula( Abs( :Predicted Ystat - :Ystat ) ) );
Column( dt, "X1" ) << Suppress Formula Eval();
Column( dt, "Y1" ) << Suppress Formula Eval();
Column( dt, "Ystat" ) << Suppress Formula Eval();
dt << Select where( :Residual 1 <= 3 );
dt << delete rows;
// 4. Creates and predicts residual column
PredictedResidual = dt2 << Neural(
 Y( :Residual 1 ),
 X( :X1 ),
 Informative Missing( 0 ),
 Validation Method( "Holdback", 0.3333 ),
 Fit( NTanH( 3 ) )
);
PredictedResidual << Save Profile Formulas;
// 5. Adds new data points, cycle starts over from 2 (lets user choose how many)
// Iteration 2
DOE( Augment Design, X( :X1 ), Y( :Ystat ), {Make Design, Make Table} );
dt << add rows();

 

 

但最后一块代码（它应该添加行的地方）并没有做任何事情。有什么建议？

 

谢谢，

凯尔

 

Re：通过JSL将增强数据点添加到现有数据表的末尾

是的，它应该是dt而不是dt2。谢谢你的纠正。如果添加rows（）;期望一个指定的值，我如何将增强设计中的更多X值添加到我的代码中指定的数据表“Sample Run 3”的末尾？对不起，如果这非常容易，我对JMP / JSL很新。

 

谢谢

Re：通过JSL将增强数据点添加到现有数据表的末尾

我相信这是做你想要的最直接的方式：

d = DOE( Augment Design, X( :X1 ), Y( :Ystat )/*, {Make Design, Make Table}*/ );
d << Make Design;
dt2 = d << Make Table;
dt << concatenate( dt2, Append to first table( 1 ) );

请记住，JMP不是Excel或R.在JMP中，您不必编写复杂的代码来完成任务。  很多时候，使用其中一个JMP平台会更容易，比如“连接”