RE：图形或分析平台假设x轴1,2,3,4 ......你好，
我正在尝试从大型数据表中按不同类别绘制来自不同行的数据。是否有任何JMP功能或平台可以自动假设x轴为1,2,3,4 ...... 同时显示7轴上的所有数值？假设在这种情况下行号不是很有用。
谢谢，
加里
RE：图形或分析平台假设x轴1,2,3,4 ......你的请求让我很困惑。您能否提供样本数据表和输出样本。RE：图形或分析平台假设x轴1,2,3,4 ......吉姆，嗨，
感谢您回复我并为此感到抱歉。这是一个示例数据表，其中包含已保存的图形构建器脚本和屏幕截图。我正在尝试将某种运行图表可视化组合在一起，但是在我的工作数据表中没有用红色圈出的列。如果我只有列“模型”和“值”，是否有任何平台可以显示如图所示？
谢谢，
加里
RE：图形或分析平台假设x轴1,2,3,4 ......您要求的似乎是为每个模型创建的运行图表。 默认情况下，它不会以2x2格式创建图表，但它会创建4个图表，而不必指定X轴
分析==>质量和流程==>控制图==>运行图表
将Value指定为Process Variable，将Model指定为By By Variable
RE：图形或分析平台假设x轴1,2,3,4 ......谢谢吉姆，
这是有帮助的，但我确实在寻找可以放入2X2子图样式的东西，因为我正在努力做一些我正在尝试做5X4的东西。
加里
RE：图形或分析平台假设x轴1,2,3,4 ......你好 @bgeaibreyi
您提到您的工作数据表中没有“Data＃”列。是否有什么阻止你制作它？看起来它只是模型中每个数据点出现的计数，您可以使用以下列公式进行计数：
Col Cumulative Sum( 1, :Model )
使用该列，您将能够像以前一样创建图形。否则，吉姆的建议很棒。
@julian
RE：图形或分析平台假设x轴1,2,3,4 ......嗨朱利安，
感谢您的建议，这是一个伟大的建议。但是，我需要做的更多过滤，每次重新定义过滤器时我都必须重置“1,2,3 ......”。运行图表运行良好，但我需要找到一种转换为子图网格样式的方法。
加里
RE：图形或分析平台假设x轴1,2,3,4 ......这是一个小脚本，它将使用运行图表输出为您提供所请求的Wrapped输出。 您可以设置要显示的图表数量，并逐行输出，直到所有模型都已绘制图表。
Names Default To Here( 1 );
dt = Current Data Table();
// Get the list of models in the data
Summarize( dt, theModels = By( :Model ) );
X = 2; // the number of graphs across
xCount = 0;
// Create the output window
NW = New Window( "Charts", Vlb = V List Box() );
// Create place to store a row of graphs
hlb = H List Box();
// Loop across all of the models and generate the graphs
For( i = 1, i <= N Items( theModels ), i++,
cc = Control Chart(
invisible,
Sample Size( 1 ),
KSigma( 3 ),
Chart Col( :Value, Run Chart( Show Center Line( 0 ) ) ),
Where( :Model == theModels[i] )
);
xCount = xCount + 1;
// Add the Model to the title of the graph
Report( cc )[Outline Box( 2 )] << set title(
(Report( cc )[Outline Box( 2 )] << get title) || " Model=" || theModels[i]
);
// Add the output to the row of graphs
hlb << append( Report( cc )[Outline Box( 2 )] );
// If this is the last graph for the row, then add the row of graphs
// to the output window
If( xCount == X,
xCount = 0;
Vlb << append( hlb );
hlb = H List Box();
);
);
// If the last row of graphs is not complete, it will not have been added
// to the output window, so check on it and if necessary, add it
If( xCount != 0,
Vlb << append( hlb )
);
RE：图形或分析平台假设x轴1,2,3,4 ......吉姆，它在网格样式上看起来更好，但根据可视化效果，这可能会做我需要的。
非常感谢！
