RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Bonjour,
J'essaie de tracer des données de différentes lignes par différentes catégories d'une grande table de données. Existe-t-il des fonctionnalités ou une plate-forme JMP pouvant automatiquement supposer que l'axe des x est égal à 1,2,3,4 ...... tout en affichant toutes les valeurs numériques sur les 7 axes? En supposant que les numéros de ligne ne sont pas très utiles dans ce scénario.
Merci,
Gary
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Votre demande m'embrouille. Pourriez-vous fournir un exemple de tableau de données et un exemple de vos résultats?RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Salut Jim,
Merci de me revenir et désolé pour la confusion. Voici un exemple de tableau de données avec un script de générateur de graphique enregistré et une capture d'écran. J'essaie de créer une sorte de visualisation de graphique d'exécution, mais la colonne entourée en rouge n'est pas disponible dans mon tableau de données. Si je n'ai que des colonnes "modèle" et "valeur", existe-t-il une plate-forme capable de visualiser comme indiqué?
Merci,
Gary
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Ce que vous demandez semble être un graphique créé pour chaque modèle. Par défaut, il ne crée pas les graphiques au format 2x2, mais il crée les 4 graphiques, sans avoir à spécifier l'axe X
Analyser ==> Qualité et processus ==> Graphique de contrôle ==> Graphique d'analyse
Spécifiez la valeur en tant que variable de processus et le modèle en tant que variable
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Merci Jim,
Ceci est utile mais je cherche en effet quelque chose qui puisse entrer dans le style des sous-parcelles 2X2 puisque je travaille quelque chose que j'essaye de faire un 5X4.
Gary
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......salut @bgeaibreyi
Vous mentionnez que vous n'avez pas la colonne "Data #" dans votre table de données de travail. Y a-t-il quelque chose qui vous empêche de le faire? Il semble que ce soit simplement un compte des occurrences de chaque point de données dans Model que vous pouvez créer avec la formule de colonne suivante:
Col Cumulative Sum( 1, :Model )
Avec cette colonne, vous pourrez créer le graphique comme vous l'avez déjà fait. Sinon, la suggestion de Jim est excellente.
@julien
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Salut julien
Merci pour la suggestion et c'est une excellente. Cependant, je dois faire plus de filtrage et redéfinir "1, 2, 3 ..." chaque fois que je redéfinis le filtre. Le tableau chronologique fonctionne très bien, mais je dois trouver un moyen de convertir le style de grille de sous-parcelle.
Gary
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Voici un petit script qui vous donnera la sortie Wrapped demandée à l’aide de la sortie Runs Chart. Vous pouvez définir le nombre de graphiques à afficher. Les résultats seront affichés ligne par ligne jusqu'à ce que tous les modèles soient représentés.
Names Default To Here( 1 );
dt = Current Data Table();
// Get the list of models in the data
Summarize( dt, theModels = By( :Model ) );
X = 2; // the number of graphs across
xCount = 0;
// Create the output window
NW = New Window( "Charts", Vlb = V List Box() );
// Create place to store a row of graphs
hlb = H List Box();
// Loop across all of the models and generate the graphs
For( i = 1, i <= N Items( theModels ), i++,
cc = Control Chart(
invisible,
Sample Size( 1 ),
KSigma( 3 ),
Chart Col( :Value, Run Chart( Show Center Line( 0 ) ) ),
Where( :Model == theModels[i] )
);
xCount = xCount + 1;
// Add the Model to the title of the graph
Report( cc )[Outline Box( 2 )] << set title(
(Report( cc )[Outline Box( 2 )] << get title) || " Model=" || theModels[i]
);
// Add the output to the row of graphs
hlb << append( Report( cc )[Outline Box( 2 )] );
// If this is the last graph for the row, then add the row of graphs
// to the output window
If( xCount == X,
xCount = 0;
Vlb << append( hlb );
hlb = H List Box();
);
);
// If the last row of graphs is not complete, it will not have been added
// to the output window, so check on it and if necessary, add it
If( xCount != 0,
Vlb << append( hlb )
);
RE: Plate-forme graphique ou d'analyse reposant sur l'axe des abscisses 1,2,3,4 ......Jim, ça aurait l'air plus joli dans un style de grille mais ça pourrait bien faire ce dont j'ai besoin en fonction de l'effet de visualisation.
Merci beaucoup!
