RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Ciao,
Sto provando a tracciare i dati da diverse righe per categorie diverse da una grande tabella di dati. C'è qualche funzionalità o piattaforma JMP che può automaticamente assumere l'asse x per essere 1,2,3,4 ...... durante la visualizzazione di tutti i valori numerici sul 7-axis? Supponendo che i numeri di riga non siano molto utili in questo scenario.
Grazie,
Gary
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......La tua richiesta mi confonde. Potresti fornire una tabella di dati di esempio e un campione del tuo output.RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Ciao Jim,
Grazie per essere tornato da me e mi dispiace per la confusione. Ecco una tabella di dati di esempio con uno script di generatore grafico salvato e uno screenshot. Sto provando a mettere insieme una sorta di visualizzazione della tabella di esecuzione, tuttavia la colonna cerchiata in rosso non è disponibile nella mia tabella di dati di lavoro. Se ho solo colonna "modello" e "valore", c'è qualche piattaforma che può visualizzare come mostrato?
Grazie,
Gary
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Quello che stai chiedendo sembra essere una tabella di esecuzione creata per ciascun modello. Per impostazione predefinita, non crea i grafici in un formato 2x2, ma crea i 4 grafici, senza dover specificare l'asse X
Analizza ==> Qualità e processo ==> Grafico di controllo ==> Esegui grafico
Specificare Valore come Variabile di processo e Modello come Variabile
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Grazie Jim,
Questo è utile, tuttavia, sto davvero cercando qualcosa che possa essere inserito nello stile delle sottotrame 2X2 poiché sto lavorando a qualcosa che sto cercando di fare un 5X4.
Gary
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Ciao @bgeaibreyi
Hai detto che non hai la colonna "Data #" nella tabella dei dati di lavoro. C'è qualcosa che ti impedisce di farlo? Sembra che si tratti semplicemente di un conteggio delle occorrenze di ciascun punto di dati all'interno del modello, che è possibile creare con la seguente formula di colonna:
Col Cumulative Sum( 1, :Model )
Con quella colonna, sarai in grado di creare il grafico come prima. Altrimenti, il suggerimento di Jim è fantastico.
@julian
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Ciao Giuliano,
Grazie per il suggerimento ed è fantastico. Tuttavia, dovrò fare più filtri che dovrei reimpostare "1, 2, 3 ...." ogni volta che ridefinisco il filtro. Il grafico delle corse funziona alla grande ma ho bisogno di trovare un modo per convertire lo stile della griglia secondaria.
Gary
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Ecco un piccolo script che ti fornirà l'output Wrapped richiesto, usando l'output di Runs Chart. È possibile impostare il numero di grafici da visualizzare e verrà visualizzato riga dopo riga, fino a quando tutti i modelli non verranno tracciati.
Names Default To Here( 1 );
dt = Current Data Table();
// Get the list of models in the data
Summarize( dt, theModels = By( :Model ) );
X = 2; // the number of graphs across
xCount = 0;
// Create the output window
NW = New Window( "Charts", Vlb = V List Box() );
// Create place to store a row of graphs
hlb = H List Box();
// Loop across all of the models and generate the graphs
For( i = 1, i <= N Items( theModels ), i++,
cc = Control Chart(
invisible,
Sample Size( 1 ),
KSigma( 3 ),
Chart Col( :Value, Run Chart( Show Center Line( 0 ) ) ),
Where( :Model == theModels[i] )
);
xCount = xCount + 1;
// Add the Model to the title of the graph
Report( cc )[Outline Box( 2 )] << set title(
(Report( cc )[Outline Box( 2 )] << get title) || " Model=" || theModels[i]
);
// Add the output to the row of graphs
hlb << append( Report( cc )[Outline Box( 2 )] );
// If this is the last graph for the row, then add the row of graphs
// to the output window
If( xCount == X,
xCount = 0;
Vlb << append( hlb );
hlb = H List Box();
);
);
// If the last row of graphs is not complete, it will not have been added
// to the output window, so check on it and if necessary, add it
If( xCount != 0,
Vlb << append( hlb )
);
RE: Piattaforma grafica o di analisi che presuppone l'asse x 1,2,3,4 ......Jim, sarebbe più bello in uno stile di griglia, ma questo potrebbe fare quello che mi serve a seconda dell'effetto di visualizzazione.
Molte grazie!
