213377_es-ES

liliconcom

Apagando suavizantes a través de JSL

Hola,

Estoy tratando de escribir una función de creación de gráficos de propósito general para lidiar con diferentes condiciones de gráficos (con o sin superposición, con o sin ajuste, etc.). La siguiente secuencia de comandos funciona para mis tres casos, pero más suave (no estoy seguro si es el ajuste lineal o de curva) está activado para los gráficos primero y segundo, y no para el tercero.

 

No creo que esté haciendo nada para encender los más suaves en mi guión. Mi pregunta es ¿cómo desactivo la (s) suave (s) a través de secuencias de comandos?

Gracias,

Cuenta

 

Clear Globals();
Names Default To Here( 1 );

//Open the file
myFile = Pick File( "Choose File" );
dtIn = Open( myFile );

//Extract Serial number
for(i=1, i<=nrow(dtIn), i++,
 dtIn:SERIAL_NUMBER[i] = regex(dtIn:SERIAL_NUMBER[i], "\w{8}");
);

dtIn:PE_COUNTS_DIE_LOGICAL_DIE_INDEX << set modeling type("Nominal");


DoGraph = function({dt, xCol, yCols, wrapCol, overlayCol},
 {default local},

 current data table(dt);
 myExpr = expr(Graph Builder(
   Size( 528, 490 ),
   Show Control Panel( 0 ),
  )
 );
 varExpr = expr(Variables());
 elementExpr = expr(Elements());
 pointsExpr = expr(Points( X ));

 xExpr = expr(X(as column(expr(xCol))));
 insert into(varExpr, name expr(xExpr), 1);
 
 if( is string(yCols),
   yExpr = expr(Y(:expr(yCols)));
   insert into(varExpr, name expr(yExpr), 2);
   nextIndex = 3;
  ,
  is list(yCols),
   nYCols = n items(yCols);
   for(i=1, i<=nYCols, i++,
    yStr = yCols[i];
    yExpr = expr(Y(as column(expr(yStr)), Position( 1 )));
    yExpr1 = eval expr(yExpr);
    insert into(varExpr, name expr(yExpr1), i+1);
    
    yPointExpr = expr(Y(expr(i)));
    yPointExpr1 = eval expr(yPointExpr);
    insert into(pointsExpr, name expr(yPointExpr1), i+1);

   );
   insert into(elementExpr, name expr(pointsExpr));
   nextIndex = nYCols + 2;
  ,
  Throw("Y must be string or list of strings");
 );

 if(length(wrapCol),
  wrapExpr = expr(Wrap(:expr(wrapCol)));
  insert into(varExpr, name expr(wrapExpr), nextIndex);
  nextIndex++;
 );
 
 if(length(overlayCol),
  overlayExpr = expr(Overlay(:expr(overlayCol)));
  insert into(varExpr, name expr(overlayExpr), nextIndex);
  nextIndex++;
 );

 insert into(myExpr, name expr(varExpr), 3);
 insert into(myExpr, name expr(elementExpr), 4);
 myExpr1 = expr(eval expr(myExpr));
 eval(myExpr1);
);

xCol = "DRIVE_LEVEL_DATA_PE_AVE_DL_AVE";
yCol = "DIE_AGE_DIE_AGE";

hpList = {
 "DRIVE_VITALS_AGE_SBS_THAT_PERFORMED_AGE_MEASUREMENT", 
 "DRIVE_VITALS_AGE_SBS_THAT_WENT_INTO_THE_HOLDING_PEN",
 "DRIVE_VITALS_AGE_OCCURANCES_OF_SBS_SKIPPED_THE_HOLDING_PEN_BECAUSE_IT_WAS_FULL",
 "DRIVE_VITALS_AGE_SBS_THAT_ABORTED_AGE_MEASUREMENT"
};

DoGraph(dtIn, xCol, "DIE_AGE_DIE_AGE", "SERIAL_NUMBER", "PE_COUNTS_DIE_LOGICAL_DIE_INDEX");
DoGraph(dtIn, xCol, "DRIVE_LEVEL_DATA_DIE_AGE_DL_AVE", "SERIAL_NUMBER", "");
DoGraph(dtIn, xCol, hpList, "SERIAL_NUMBER", "");

Re: Apagar suavizantes a través de JSL

Podría manipular las preferencias del Generador de gráficos para que lo más suave nunca aparezca en primer lugar. O podrías hacer este tipo de cosas:

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
      Show Control Panel( 0 ),
      Variables( X( :weight ), Y( :height ) ),
      Elements( Points( X, Y, Legend( 5 ) ), Smoother( X, Y, Legend( 6 ) ) )
     );

Wait(2);
gbb = Report( gb )[Graph Builder Box( 1 )];
Print(gbb << Get Elements( 1, 1 ));
gbb << removeElement(1, 1, 2);
Print(gbb << Get Elements( 1, 1 ));

Re: Apagar suavizantes a través de JSL

Hola, Ian,

 

Gracias por su respuesta.  Idealmente, me gustaría evitar que la suavidad se ponga en primer lugar.  Intenté descubrir cómo manipular las preferencias del generador de gráficos, pero el único elemento de escrutinio relacionado que encontré fue "Ignorar las preferencias de la plataforma (1)", y esto no tuvo ningún impacto.  Una cosa que me preocupa es que el comportamiento predeterminado varía entre mis tres casos.

 

¿Alguna sugerencia sobre qué synatax de scripting puede acceder a las preferencias del generador de gráficos?

 

Gracias,

Cuenta

Re: Apagar suavizantes a través de JSL¿Hay una ironía que escribí mal la sintaxis? De todos modos, pude usar la GUI de JMP para cambiar la preferencia del generador de gráficos, pero al final otros usarán mi código, por lo que necesitaría escribir el comportamiento de las preferencias para que diferentes usuarios obtengan el mismo resultado.Re: Apagar suavizantes a través de JSL

Encontré la bala mágica después de una pequeña excavación:

 

establecer las preferencias de la plataforma (generador de gráficos (Continuous Smoother (0)));

 

Gracias por apuntarme en la dirección correcta Ian.