212972_zh-CN

liliconcom

加入不同大小的数据集

 

我试图将数据点从一个数据表拉到另一个数据表。以上就是一个例子。一个简单的连接似乎没有让我到达我需要去的地方。实际上左边的数据表非常大（800K行）。我想基于jar id和seq id在两个数据表之间进行匹配。然后使用TOTE ID在左侧表格中创建一个新列，并使用右侧表格（数量小得多的70k行）中的数据填充，并成功匹配。因此，右侧数据表中的任何给定TOTE ID将被重复填充左侧的表格。谢谢您的帮助。

Re：加入不同大小的数据集

您想要做的是数据表的简单连接。

     表==>加入

下面是将进行连接的JSL，但这可以在交互模式下轻松完成

names default to here(1);

// Create Sample data tables
dt1 = New Table( "Base",
 Add Rows( 10 ),
 New Column( "Tube ID",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] )
 ),
 New Column( "JAR ID",
  Character,
  "Nominal",
  Set Values(
   {"XXXY1", "XXXY1", "XXXY2", "XXXY2", "XXXY3", "XXXY3", "XXXY1", "XXXY1",
   "XXXY3", "XXXY3"}
  ),
  Set Display Width( 92 )
 ),
 New Column( "SEQ ID",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1001, 1001, 1002, 1002, 1003, 1003, 1001, 1001, 1003, 1003] ),
  Set Display Width( 131 )
 )
);
dt2 = New Table( "Lookup",
 Add Rows( 5 ),
 New Column( "JAR ID",
  Character,
  "Nominal",
  Set Values( {"XXXY1", "XXXY2", "XXXY3", "XXXY4", "XXXY5"} ),
  Set Display Width( 72 )
 ),
 New Column( "SEQ ID",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1001, 1002, 1003, 1004, 1005] ),
  Set Display Width( 80 )
 ),
 New Column( "TOTE ID",
  Character,
  "Nominal",
  Set Values( {"AAA1", "AAA2", "AAA3", "AAA4", "AAA5"} )
 )
);

// Join the tables
dtJoin = dt << Join(
 With( dt2 ),
 Merge Same Name Columns,
 Match Flag( 0 ),
 By Matching Columns( :JAR ID = :JAR ID, :SEQ ID = :SEQ ID ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 1, 0 ),
 Preserve main table order( 1 ),
 Output Table( "Joined" )
);

Re：加入不同大小的数据集谢谢你的帮助！我没有检查是否包括不匹配。有它的工作，谢谢你。Re：加入不同大小的数据集

您还可以使用“表”>“更新”命令。

dt1 << Update(
 With( dt2 ),
 Match Columns( :JAR ID = :JAR ID, :SEQ ID = :SEQ ID ),
 Add Columns from Update table( :TOTE ID )
);