212373_ko-KR

liliconcom

JSL 사양을 설정하면 "그래프 참조 선으로 표시"

나는 어딘가에서 빌려온 위대한 스크립트를 가지고 있으며 여러 개의 spec 한도를 가져 와서 각 열에 할당합니다. "그래프 참조 행으로 표시"에 대한 Spec Limits의 상자를 체크하기 위해 열의 스펙을 편집하는 방법이 있습니까? 지금 당장이 작업을 수동으로 수행해야합니다.

 

 

dt = Current Data Table();
dt2 = Open();
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables",
   pList << append( datacolbox << get selected )
  ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  pvars = ":" || thelist[1];
  For( i = 2, i <= N Items( thelist ), i++,
   pvars = pvars || ",:" || thelist[i]
  );
  Eval(
   Parse(
    "obj = dt << Process Capability(
 Process Variables(" || pvars ||
    " ),
 Spec Limits( Import Spec Limits( dt2 ) )
);"
   )
  );
  obj << Save Spec Limits as Column Properties;
  obj << close window;
  nw << close window;
 )
);

감사!

제목 : Re : JSL "그래프 참조 선으로 표시"

코드를 올바르게 해석하고 있다면 한계 테이블에서 데이터 테이블의 열 속성으로 한도를 복사하는 것입니다.  이 경우 JMP 14의 사양 관리 제한 기능을 살펴볼 수 있습니다.

Manage Spec Limits(  );

그러나 당신이 지금하고있는 방식대로 계속하기를 원한다면, 스크립트의 수정으로 쇼 한계를 설정할 수 있습니다

Names Default To Here( 1 );
dt = open();
dt2 = Data Table( "limits" );
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables", pList << append( datacolbox << get selected ) ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  // Loop across all of the item is theList and process
  // the data
  For( i = 1, i <= N Items( theList ), i++,
   theRow = dt2 << get rows where( :Process == theList[i] );
   If( N Rows( theRow ) > 0, 
    // Change theRow to a scaler
    theRow = theRow[1];
    // Set the spec limits in the dt data table by reading
    // the values from the dt2(limits) data table
    Eval(
     Substitute(
       Expr(
        Column( dt, theList[i] ) <<
        set property(
         "spec limits",
         {__LSL__, __USL__, __Target__, Show Limits( 1 )}
        )
       ),
      Expr( __LSL__ ), Column( dt2, "LSL" )[theRow],
      Expr( __USL__ ), Column( dt2, "USL" )[theRow],
      Expr( __Target__ ), Column( dt2, "Target" )[theRow]
     )
    );
   );
  );
  
  nw << close window;
 )
);