212373_fr-FR

liliconcom

JSL Activer les limites de spécification "Afficher sous forme de lignes de référence de graphique"

J'ai un excellent script que j'ai emprunté quelque part pour importer plusieurs limites de spécifications et les affecter à chaque colonne. Existe-t-il un moyen, lors de la modification de la spécification d'une colonne, de cocher également la case sous Limites de spécification pour "Afficher sous forme de lignes de référence de graphique" ? Pour l'instant, je dois le faire manuellement.

 

 

dt = Current Data Table();
dt2 = Open();
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables",
   pList << append( datacolbox << get selected )
  ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  pvars = ":" || thelist[1];
  For( i = 2, i <= N Items( thelist ), i++,
   pvars = pvars || ",:" || thelist[i]
  );
  Eval(
   Parse(
    "obj = dt << Process Capability(
 Process Variables(" || pvars ||
    " ),
 Spec Limits( Import Spec Limits( dt2 ) )
);"
   )
  );
  obj << Save Spec Limits as Column Properties;
  obj << close window;
  nw << close window;
 )
);

Merci!

Re : JSL activant les limites de spécification "Afficher sous forme de lignes de référence de graphique"

Si j'interprète correctement votre code, ce que vous faites est de copier vos limites de la table des limites dans les propriétés de colonne de votre table de données.Si tel est le cas, vous pouvez consulter la fonctionnalité Gérer les limites des spécifications dans JMP 14

Manage Spec Limits(  );

Cependant, si vous souhaitez simplement continuer comme vous le faites, voici une modification de votre script qui définira les limites d'affichage

Names Default To Here( 1 );
dt = open();
dt2 = Data Table( "limits" );
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables", pList << append( datacolbox << get selected ) ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  // Loop across all of the item is theList and process
  // the data
  For( i = 1, i <= N Items( theList ), i++,
   theRow = dt2 << get rows where( :Process == theList[i] );
   If( N Rows( theRow ) > 0, 
    // Change theRow to a scaler
    theRow = theRow[1];
    // Set the spec limits in the dt data table by reading
    // the values from the dt2(limits) data table
    Eval(
     Substitute(
       Expr(
        Column( dt, theList[i] ) <<
        set property(
         "spec limits",
         {__LSL__, __USL__, __Target__, Show Limits( 1 )}
        )
       ),
      Expr( __LSL__ ), Column( dt2, "LSL" )[theRow],
      Expr( __USL__ ), Column( dt2, "USL" )[theRow],
      Expr( __Target__ ), Column( dt2, "Target" )[theRow]
     )
    );
   );
  );
  
  nw << close window;
 )
);