212373_es-ES

liliconcom

JSL Activación de límites de especificaciones "Mostrar como líneas de referencia de gráfico"

Tengo un gran script que tomé prestado de algún lugar para importar múltiples límites de especificaciones y asignarlos a cada columna. ¿Hay alguna forma al editar la especificación de una columna para marcar también la casilla debajo de Límites de especificación para "Mostrar como líneas de referencia de gráficos"? Ahora mismo tengo que hacer esto manualmente.

 

 

dt = Current Data Table();
dt2 = Open();
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables",
   pList << append( datacolbox << get selected )
  ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  pvars = ":" || thelist[1];
  For( i = 2, i <= N Items( thelist ), i++,
   pvars = pvars || ",:" || thelist[i]
  );
  Eval(
   Parse(
    "obj = dt << Process Capability(
 Process Variables(" || pvars ||
    " ),
 Spec Limits( Import Spec Limits( dt2 ) )
);"
   )
  );
  obj << Save Spec Limits as Column Properties;
  obj << close window;
  nw << close window;
 )
);

¡Gracias!

Re: JSL Activación de límites de especificaciones "Mostrar como líneas de referencia de gráficos"

Si estoy interpretando su código correctamente, lo que está haciendo es copiar sus límites de la tabla de límites, en las propiedades de columna para su tabla de datos.  Si este es el caso, es posible que desee consultar la capacidad Administrar límites de especificaciones en JMP 14

Manage Spec Limits(  );

Sin embargo, si solo desea continuar de la manera en que lo está haciendo, aquí hay una modificación de su script que establecerá los Límites de Mostrar

Names Default To Here( 1 );
dt = open();
dt2 = Data Table( "limits" );
Current Data Table( dt );
nw = New Window( "Select Process Variables",
 Text Box( "Selection Columns" ),
 H List Box(
  datacolbox = Col List Box( all ),
  Button Box( "Process Variables", pList << append( datacolbox << get selected ) ),
  pList = List Box( {} )
 ),
 Button Box( "OK",
  thelist = plist << get items;
  // Loop across all of the item is theList and process
  // the data
  For( i = 1, i <= N Items( theList ), i++,
   theRow = dt2 << get rows where( :Process == theList[i] );
   If( N Rows( theRow ) > 0, 
    // Change theRow to a scaler
    theRow = theRow[1];
    // Set the spec limits in the dt data table by reading
    // the values from the dt2(limits) data table
    Eval(
     Substitute(
       Expr(
        Column( dt, theList[i] ) <<
        set property(
         "spec limits",
         {__LSL__, __USL__, __Target__, Show Limits( 1 )}
        )
       ),
      Expr( __LSL__ ), Column( dt2, "LSL" )[theRow],
      Expr( __USL__ ), Column( dt2, "USL" )[theRow],
      Expr( __Target__ ), Column( dt2, "Target" )[theRow]
     )
    );
   );
  );
  
  nw << close window;
 )
);