J'utilise actuellement JMP 12 pour mon analyse. J'ai besoin d'apports techniques sur l'aspect suivant
- J'utilise un modèle à effets mixtes pour évaluer si la différence entre les sites est significative
- J'aimerais connaître la valeur wald p correspondant à l'effet aléatoire Site *temps [lot] pour déduire si l'impact est significatif ou non
S'il vous plaît laissez-moi savoir s'il y a une possibilité, voir les informations sur la valeur p de Wald dans la version 12. S'il n'y a pas d'option, veuillez me faire savoir la formule ou la procédure qui peut être utilisée pour calculer la valeur p de Wald.
Est-il possible de partager un script pour générer la valeur wald p dans JMP version 12
Dans l'attente de votre aide à cet égard dès que possible car c'est essentiel pour notre projet
Salut @Dinesh ,
Chose sûre. Cette valeur p est calculée avec Z comme distribution de référence, et le tableau des composants de la variance contient tous les ingrédients pour obtenir la statistique de test. Vous pouvez enregistrer le tableau vous-même (clic droit > transformer en tableau de données), puis créer deux nouvelles colonnes, le rapport de la composante de variance à l'erreur standard, puis une deuxième colonne, une recherche de ce quotient dans la distribution z. , avec quelques calculs simples pour trouver la proportion plus extrême que cette valeur dans la distribution de référence. En voici un exemple :
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Cholesterol Stacked.jmp" );
platform = dt << Fit Model(
Y( :Y ),
Effects(
:Treatment,
:Month,
:Name( "AM/PM" ),
:Treatment * :Month,
:Treatment * :Name( "AM/PM" ),
:Month * :Name( "AM/PM" ),
:Treatment * :Month * :Name( "AM/PM" )
),
Random Effects(
:Patient[:Treatment],
:Patient * :Month[:Treatment],
:Patient * :Name( "AM/PM" )[:Treatment],
:Patient * :Month * :Name( "AM/PM" )[:Treatment]
),
NoBounds( 1 ),
Personality( "Standard Least Squares" ),
Method( "REML" ),
Emphasis( "Minimal Report" ),
Run(
:Y << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ), Lack of Fit( 0 ),
Scaled Estimates( 0 ), Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 0 ), Plot Effect Leverage( 0 ),
Plot Residual by Normal Quantiles( 0 )}
)
);
Wait( 0 );
Report( platform )[Outline Box( "Response Y" )][Outline Box( "REML Variance Component Estimates" )][
Table Box( 1 )] << Make Into Data Table;
Report( platform ) << Close Window;
New Column( "Var Component/Std Error",
Numeric,
"Continuous",
Format( "Best", 12 ),
Formula( :Var Component / :Std Error ),
Set Selected
);
New Column( "Prob > |Z|",
Numeric,
"Continuous",
Format( "Best", 12 ),
Formula( (1 - Normal Distribution( :Name( "Var Component/Std Error" ) )) * 2 ),
Set Selected
);
Cela renverra ce qui suit (affichant JMP 14 afin que vous puissiez voir le calcul par JMP de la valeur P de Wald, dont vous pouvez confirmer qu'il est le même que celui calculé dans la méthode que j'ai décrite ci-dessus).
@julien
Salut @Dinesh ,
Les valeurs P ne sont pas affichées pour les composants de variance dans JMP 12 ; ces valeurs p ont été ajoutées dans JMP 13. Je me rends compte que ce n'est pas exactement ce que vous recherchez, mais vous pouvez utiliser les intervalles de confiance de la même manière que le test d'hypothèse à un niveau de confiance alpha de 1 en regardant si 0 est contenu dans l'intervalle. Si ce n'est pas le cas, votre valeur p (pour le test d'hypothèse correspondant) est < niveau de confiance 1. Si vous devez modifier ce niveau de confiance, vous pouvez le faire lorsque vous lancez Fit Model : cliquez sur le triangle rouge supérieur dans la fenêtre de lancement > Niveau Alpha. 
J'espère que ça a aidé!
@julien
