저는 현재 분석에 JMP 12를 사용하고 있습니다. 다음 측면에 대한 기술적 입력이 필요합니다.
- 사이트 간 차이가 중요한지 평가하기 위해 혼합 효과 모델을 사용하고 있습니다.
- 영향이 유의미한지 아닌지 추론하기 위해 Random effect Site *time[batch]에 해당하는 wald p 값을 알고 싶습니다.
버전 12의 Wald p 값 정보를 참조할 가능성이 있으면 알려 주시기 바랍니다. 옵션이 없는 경우 Wald P 값을 계산하는 데 사용할 수 있는 공식이나 절차를 알려주십시오.
JMP 버전 12에서 Wald p 값을 생성하기 위한 스크립트를 공유할 수 있습니까?
우리 프로젝트에 매우 중요하므로 가능한 한 빨리 이와 관련하여 귀하의 지원을 기대합니다.
안녕 @디네쉬 ,
확실한 것. 해당 p-값은 Z를 참조 분포로 사용하여 계산되며 분산 성분 표에는 검정 통계량을 얻는 데 필요한 모든 성분이 있습니다. 테이블을 직접 저장할 수 있습니다(마우스 오른쪽 버튼 클릭 > 데이터 테이블 만들기). 그런 다음 표준 오차에 대한 분산 구성 요소의 비율인 두 개의 새 열을 만든 다음 z-분포에서 해당 몫을 조회하는 두 번째 열을 만들 수 있습니다. , 간단한 산술을 사용하여 기준 분포의 값보다 더 극단적인 비율을 찾습니다. 그 예는 다음과 같습니다.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Cholesterol Stacked.jmp" );
platform = dt << Fit Model(
Y( :Y ),
Effects(
:Treatment,
:Month,
:Name( "AM/PM" ),
:Treatment * :Month,
:Treatment * :Name( "AM/PM" ),
:Month * :Name( "AM/PM" ),
:Treatment * :Month * :Name( "AM/PM" )
),
Random Effects(
:Patient[:Treatment],
:Patient * :Month[:Treatment],
:Patient * :Name( "AM/PM" )[:Treatment],
:Patient * :Month * :Name( "AM/PM" )[:Treatment]
),
NoBounds( 1 ),
Personality( "Standard Least Squares" ),
Method( "REML" ),
Emphasis( "Minimal Report" ),
Run(
:Y << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ), Lack of Fit( 0 ),
Scaled Estimates( 0 ), Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 0 ), Plot Effect Leverage( 0 ),
Plot Residual by Normal Quantiles( 0 )}
)
);
Wait( 0 );
Report( platform )[Outline Box( "Response Y" )][Outline Box( "REML Variance Component Estimates" )][
Table Box( 1 )] << Make Into Data Table;
Report( platform ) << Close Window;
New Column( "Var Component/Std Error",
Numeric,
"Continuous",
Format( "Best", 12 ),
Formula( :Var Component / :Std Error ),
Set Selected
);
New Column( "Prob > |Z|",
Numeric,
"Continuous",
Format( "Best", 12 ),
Formula( (1 - Normal Distribution( :Name( "Var Component/Std Error" ) )) * 2 ),
Set Selected
);
그러면 다음이 반환됩니다(JMP 14를 표시하면 JMP의 Wald P-값 계산을 확인할 수 있습니다. 이는 위에서 설명한 방법으로 계산한 것과 동일함을 확인할 수 있습니다).
@줄리안
안녕 @디네쉬 ,
JMP 12에서는 분산 성분에 대한 P-값이 표시되지 않습니다. 이러한 p-값은 JMP 13에 추가되었습니다. 나는 이것이 정확히 당신이 찾고 있는 것이 아니라는 것을 알고 있지만 구간에 0이 포함되어 있는지 확인하여 1-신뢰 수준의 알파에서 가설 테스트와 거의 동일한 방식으로 신뢰 구간을 사용할 수 있습니다. 그렇지 않은 경우 해당 가설 검정에 대한 p-값은 < 1-신뢰 수준입니다. 이 신뢰 수준을 변경해야 하는 경우 Fit Model을 시작할 때 변경할 수 있습니다. 시작 창에서 상단 빨간색 삼각형 > 알파 수준을 클릭합니다. 
이것이 도움이 되길 바랍니다!
@줄리안
