210933_fr-FR

liliconcom

Sélectionner plusieurs colonnes et mettre à jour la valeur de la colonne manquante

Bonjour,

Je suis nouveau dans les scripts JMP. Je travaille sur un script pour sélectionner plusieurs colonnes contenant le mot "Censor" et mettre à jour la valeur manquante. ci-dessous un ensemble d'exemples de données. J'ai répertorié trois colonnes Censor A, Censor B et Censor C. mais dans le monde réel, le nombre de colonnes peut être différent à chaque fois. je devrai donc sélectionner les colonnes qui contiennent le travail " Censor ", puis mettre à jour toutes les valeurs manquantes avec " S ". Puis-je faire cela en JSL? J'apprends toujours à écrire des scripts, mais je n'ai pas trouvé de moyen dans l'aide de JMP.

 

Censeur A	Censeur B	Censeur C
F		F
F	F
F
		F
	F	F
F

Re : Sélectionner plusieurs colonnes et mettre à jour la valeur de la colonne manquante

Voici une modification de mon script initial pour faire ce que je pense que vous voulez .....

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example 2",
 Add Rows( 6 ),
 New Column( "Censor A",
  Character,
  "Nominal",
  Set Values( {"F", "F", "F", "", "", "F"} )
 ),
 New Column( "Censor B",
  Character,
  "Nominal",
  Set Values( {"", "F", "", "", "F", ""} )
 ),
 New Column( "Censor C",
  Character,
  "Nominal",
  Set Values( {"F", "", "", "F", "F", ""} )
 ),
 New Column( "Setting Column",
  Character,
  "Nominal",
  Set Values( {"Z", "X", "Y", "W", "P", "Q"} )
 )
);

// Get the names of all of the columns
colNames = dt << get column names( string );

// Loop across all columns and if a Censor column
// then process
For( i = 1, i <= N Items( colNames ), i++,
 If( Left( colNames[i], 6 ) == "Censor",
  dt << select where( As Column( colNames[i] ) == "" );
  // If blanks are found then process
  rowMat = dt << get selected rows;
  If( N Rows( rowMat ) > 0,
   For( k = 1, k <= N Rows( rowMat ), k++,
    Column( colNames[i] )[rowMat[k]] = :Setting Column[rowMat[k]]
   )
  );
 )
);

Re : Sélectionner plusieurs colonnes et mettre à jour la valeur de la colonne manquanteMerci pour ton aide! Voici une autre question. pour le cas ci-dessus, comment puis-je mettre à jour la valeur manquante avec la valeur dans une autre colonne ?Re : Sélectionner plusieurs colonnes et mettre à jour la valeur de la colonne manquanteMerci!Re : Sélectionner plusieurs colonnes et mettre à jour la valeur de la colonne manquante

Voici un script simple qui accomplira le remplissage des cellules manquantes

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 6 ),
 New Column( "Censor A",
  Character,
  "Nominal",
  Set Values( {"F", "F", "F", "", "", "F"} )
 ),
 New Column( "Censor B",
  Character,
  "Nominal",
  Set Values( {"", "F", "", "", "F", ""} )
 ),
 New Column( "Censor C",
  Character,
  "Nominal",
  Set Values( {"F", "", "", "F", "F", ""} )
 )
);

// Get the names of all of the columns
colNames = dt << get column names( string );

// Loop across all columns and if a Censor column
// then process
For( i = 1, i <= N Items( colNames ), i++,
 If( Left( colNames[i], 6 ) == "Censor",
  dt << select where( As Column( colNames[i] ) == "" );
  // If blanks are found then process
  If( N Rows( dt << get selected rows ) > 0,
   As Column( colNames[i] )[dt << get selected Rows] = "S"
  );
 )
);