210933_it-IT

liliconcom

Seleziona più colonne e aggiorna il valore della colonna mancante

Ciao,

Sono nuovo nello scripting JMP. Sto lavorando su uno script per selezionare più colonne che contengono la parola "Censore" e aggiornare il valore mancante. di seguito è riportato un insieme di dati di esempio. Ho elencato tre colonne Censor A, Censor B e Censor C. ma nel mondo reale il numero di colonne può essere diverso ogni volta. quindi dovrò selezionare le colonne che contengono il lavoro "Censor", quindi aggiornare tutti i valori mancanti con "S". Posso farlo in JSL? Sto ancora imparando a creare script, ma non riesco a trovare un modo nella Guida di JMP.

 

Censore A	Censore B	Censore C
F		F
F	F
F
		F
	F	F
F

Ri: Seleziona più colonne e aggiorna il valore della colonna mancante

Ecco una modifica al mio script iniziale per fare quello che penso tu voglia.....

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example 2",
 Add Rows( 6 ),
 New Column( "Censor A",
  Character,
  "Nominal",
  Set Values( {"F", "F", "F", "", "", "F"} )
 ),
 New Column( "Censor B",
  Character,
  "Nominal",
  Set Values( {"", "F", "", "", "F", ""} )
 ),
 New Column( "Censor C",
  Character,
  "Nominal",
  Set Values( {"F", "", "", "F", "F", ""} )
 ),
 New Column( "Setting Column",
  Character,
  "Nominal",
  Set Values( {"Z", "X", "Y", "W", "P", "Q"} )
 )
);

// Get the names of all of the columns
colNames = dt << get column names( string );

// Loop across all columns and if a Censor column
// then process
For( i = 1, i <= N Items( colNames ), i++,
 If( Left( colNames[i], 6 ) == "Censor",
  dt << select where( As Column( colNames[i] ) == "" );
  // If blanks are found then process
  rowMat = dt << get selected rows;
  If( N Rows( rowMat ) > 0,
   For( k = 1, k <= N Rows( rowMat ), k++,
    Column( colNames[i] )[rowMat[k]] = :Setting Column[rowMat[k]]
   )
  );
 )
);

Ri: Seleziona più colonne e aggiorna il valore della colonna mancanteGrazie per l'aiuto! Ecco un'altra domanda. per il caso precedente, come posso aggiornare il valore mancante con il valore in un'altra colonna?Ri: Seleziona più colonne e aggiorna il valore della colonna mancanteGrazie!Ri: Seleziona più colonne e aggiorna il valore della colonna mancante

Ecco un semplice script che completerà la compilazione delle celle mancanti

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 6 ),
 New Column( "Censor A",
  Character,
  "Nominal",
  Set Values( {"F", "F", "F", "", "", "F"} )
 ),
 New Column( "Censor B",
  Character,
  "Nominal",
  Set Values( {"", "F", "", "", "F", ""} )
 ),
 New Column( "Censor C",
  Character,
  "Nominal",
  Set Values( {"F", "", "", "F", "F", ""} )
 )
);

// Get the names of all of the columns
colNames = dt << get column names( string );

// Loop across all columns and if a Censor column
// then process
For( i = 1, i <= N Items( colNames ), i++,
 If( Left( colNames[i], 6 ) == "Censor",
  dt << select where( As Column( colNames[i] ) == "" );
  // If blanks are found then process
  If( N Rows( dt << get selected rows ) > 0,
   As Column( colNames[i] )[dt << get selected Rows] = "S"
  );
 )
);