How can the comparison result be obtained directly without adding auxiliary columns？

lwx228

Hello, everyone!

The yield of the two tables of the same specification is different,
Can the comparison result be obtained directly without adding auxiliary columns:
Results are obtained in table 2: if the yield in table 1 is larger than that in table 2, the result is 1; otherwise, the result is 0.

 

d1 = Open( "$SAMPLE_DATA/Trial1.jmp" );
d2 = Open( "$SAMPLE_DATA/Trial2.jmp" );

 

Thanks!

txnelson

I am a little confused by what you mean when you say "obtained directly without adding auxiliary columns";  I have put together 2 simple scripts.  The first one adheres strictly to your statement, in that it creates no unnecessary columns to produce the results.  However, this method is inefficient, and will not scale up very well if the data tables get large

 Names Default To Here( 1 );

d1 = Open( "$SAMPLE_DATA/Trial1.jmp" );
d2 = Open( "$SAMPLE_DATA/Trial2.jmp" );

// Create the new column by comparing values between the data tables
d2 << New Column( "Result",
	formula(
		compare = d1:yield[((d1 <<
		get rows where(
			d1:popcorn == d2:popcorn & d1:oil amt == d2:oil amt & 
			d1:batch == d2:batch ))[Row()])];
		If( compare > d2:yield[Row()],
			theResult = 1,
			theResult = 0
		);
		theResult;
	)
);

// Change the values of the column Result to static values by removing
// the formula
d2:Result << delete property( "formula" );

The second example is very efficient, but uses temporary additional columns, but the results end up the same:

Names Default To Here( 1 );

d1 = Open( "$SAMPLE_DATA/Trial1.jmp" );
d2 = Open( "$SAMPLE_DATA/Trial2.jmp" );

// Temp. change of the name of the Yield column in data table 1
d1:yield << set name("yield1");

// Copy the Yield1 column to data table 2
d2 << Update(
	With( d1 ),
	Match Columns( :popcorn = :popcorn, :oil amt = :oil amt, :batch = :batch ),
	Add Columns from Update table( :yield1 )
);

// Change the Yield1 column in data table 1 back to it's original name
d1:yield1 << set name("yield");

// Create and calculate the Result column in data table 2
d2 << new column("Result", formula(
	If(:yield1 > :yield, 1,0);
));

// Change the values of the column Result to static values by removing
// the formula
d2:Result << delete property( "formula" );

// Delete the no longer needed Yield1 column
d2<<delete columns("Yield1");