Hallo @ram_asra_gmail_ ,
Ich glaube, ich verstehe jetzt, was Sie beschrieben haben, aber lassen Sie es mich noch einmal wiederholen, um sicherzugehen. Overlay Plot liefert ein Ergebnis wie dieses:
Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
Overlay Plot( X( :NPN2 ), Y( :NPN1 ), Grouping( :SITE ), Overlay Groups, :NPN1( Connect Color( 40 ), Overlay Marker( 8 ) ) );
Was Sie bevorzugen, da die Markierungen für jede Gruppe (Site in Ihrem Beispiel) in übereinander gestapelten Ebenen vorhanden sind. Mit anderen Worten, alle Standort-5-Markierungen werden auf Standort-4-Markierungen gezeichnet, die alle auf Standort-3-Markierungen gezeichnet werden usw. Wie Sie bemerkt haben, macht Graph Builder dasselbe:
Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
Graph Builder( Show Control Panel( 0 ),
Variables( X( :NPN2 ), Y( :NPN1 ), Overlay( :SITE ) ),
Elements( Points( X, Y, Legend( 5 ) ) )
);
Aus Gründen, die ich gleich erläutern werde, tut Bivariate from Fit Y by X dies jedoch nicht:
Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
Bivariate( Y( :NPN1 ), X( :NPN2 ), SendToReport( Dispatch( {}, "Bivar Plot", FrameBox, {Row Legend( SITE )} ) ) );
Ich kann mir sicher vorstellen, dass Sie vielleicht bevorzugen, was Overlay Plot und Graph Builder tun! Lassen Sie mich versuchen zu erklären, warum sich diese Plattformen unterscheiden, und dann einige Vorschläge machen, von denen ich hoffe, dass sie helfen.
Der Grund für den Unterschied zwischen diesen Plattformen besteht darin, dass Overlay Plot und Graph Builder, die absichtlich für den Umgang mit mehr als zwei Variablen entwickelt wurden, die Markierungen in Schichten basierend auf der darüber liegenden Variablen zeichnen. Sie können dies selbst sehen, wenn Sie mit der rechten Maustaste klicken und eines der Diagramme anpassen. Graph Builder und Overlay Plot sehen folgendermaßen aus:
Und Fit Y by X (bivariat) sieht so aus:
Beachten Sie die fünf Markierungsebenen in Graph Builder / Overlap Plot (eine für jede Site)? Diese Ebenen steuern die Zeichnungsreihenfolge und damit die Überlappungsreihenfolge. Beachten Sie, dass es nur eine Markierungsebene für Y nach X anpassen gibt, was wiederum bedeutet, dass Punkte beim Zeichnen keine Ebenen in Bezug auf eine andere Variable berücksichtigen können. Wenn Sie eine Zeilenlegende erstellen, wie Sie es in Y nach X anpassen getan haben (Rechtsklick > Zeilenlegende), stellt JMP eine Legende bereit, mit der Sie die Punkte einfärben oder markieren können, aber das ändert das Zeichenverhalten der Plattform nicht grundlegend. Schließlich ist Fit Y by X für ein y und ein x ausgelegt, wie der Name schon sagt, was bedeutet, dass es nicht dafür ausgelegt ist, die Markierungen in Ebenen zu zeichnen, selbst wenn Sie eine Legende haben, um sie zu identifizieren. Es tut mir leid zu sagen, dass es keine schnelle Lösung gibt (die mir bekannt ist), um ein bivariates Diagramm „Y by X anpassen“ zu erzwingen, um die Punkte in Ebenen wie Graph Builder und Overlay Plot zu zeichnen.
Ich habe einige Vorschläge versprochen. Ich gehe davon aus, dass Sie Fit Y by X für Analysen verwenden, daher ist mein erster Vorschlag, dass Sie alle erforderlichen Analysearbeiten in Fit Y by X durchführen, aber dann Graph Builder verwenden, um Ihr endgültiges Bild zu erstellen, das Sie mit anderen teilen . So arbeite ich die meiste Zeit – so sehr ich Fit Y by X (und andere Plattformen) mag, ich habe eine viel größere kreative Kontrolle über die Diagramme, die ich in Graph Builder erstelle, also ist das meine erste Wahl Werkzeug zum Erstellen einer Grafik, die ich teilen möchte. Das hört sich vielleicht nicht so sehr nach einer Lösung an, sondern vielmehr nach einem Vorstoß, einen anderen Teil von JMP zu verwenden, aber manchmal IST das wirklich die beste Lösung!
Eine weitere Option besteht darin, die By-Variable zu nutzen, wenn Fit Y by X gestartet wird, z. B.:
Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
Bivariate( Y( :NPN1 ), X( :NPN2 ), By( :SITE ) );
Zugegebenermaßen ist dies nicht dasselbe, da Sie dadurch separate Diagramme und separate Anpassungsmodelle nach Gruppe erhalten. Aber bei einer großen Anzahl überlappender Punkte und was nach einer echten Notwendigkeit klingt, bestimmte Punkte zu sehen, ist dies vielleicht eine Option?
Wenn schließlich alle Zeilen für die Analyse zusammengehalten werden müssen, Sie aber die Punkte für jede Gruppe separat sehen müssen, kann ein lokaler Datenfilter, bei dem nur "Anzeigen" aktiviert ist, ausreichen.
Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );
Bivariate(
Y( :NPN1 ),
X( :NPN2 ),
Automatic Recalc( 1 ),
Fit Line( {Line Color( {212, 73, 88} )} ),
Local Data Filter(
Mode( Include( 0 ) ),
Add Filter(
columns( :SITE ),
Where( :SITE == 5 ),
Display( :SITE, Size( 181, 85 ), List Display )
)
)
);
Dadurch können Sie durch die Ebenen der Gruppierungsvariablen schalten, um alle unverdeckten Punkte anzuzeigen, aber da "Einschließen" nicht aktiviert ist, hat der lokale Datenfilter keinen Einfluss darauf, welche Zeilen für die Analyse verfügbar sind.
Ich hoffe, dass etwas hier ein wenig hilft, und ich hoffe auch, dass es ein wenig Klarheit darüber gibt, warum sich jmp so verhält, wie es sich verhält.
@julianisch
leider kann ich kein bild hochladen. aber unten ist die jsl. Wenn Sie laufen, wird es einen deutlichen Unterschied zwischen Bivariat und Ovlay zeigen (& Overlay im Grph Builder). Es wird zeigen, wie die Daten für verschiedene Gruppen nur zufällig in bivariat gemischt werden, anstatt ein klares Niveau zu definieren, das in der Überlagerung definiert ist.
Danke
RAM
open("C:\Program Files\SAS\JMP\14\Samples\Data\Semiconductor Capability.jmp");
Graph Builder(
Size( 450, 306 ),
Show Control Panel( 0 ),
Variables( X( :NPN2 ), Y( :NPN1 ), Overlay( :SITE ) ),
Elements( Points( X, Y, Legend( 5 ) ) )
);
Bivariate(
Y( :NPN1 ),
X( :NPN2 ),
Automatic Recalc( 1 ),
SendToReport(
Dispatch(
{},
"Bivar Plot",
FrameBox,
{Row Legend(
SITE,
Color( 1 ),
Color Theme(
{"My_Color", 8193, {{53, 171, 50}, {255, 0, 0}, {33, 53, 237},
{225, 225, 0}, {160, 66, 255}, {255, 128, 0}, {150, 128, 0},
{166, 166, 166}}}
),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
)
)
);
Overlay Plot(
X( :NPN2 ),
Y( :NPN1 ),
Grouping( :SITE ),
Overlay Groups,
:NPN1( Connect Color( 40 ), Overlay Marker( 8 ) )
);Hallo @ram_asra_gmail_ ,
Ich bin sicher, wir finden einen Weg, um das zu bekommen, wonach Sie suchen! Könnten Sie ein Bild der Art von Diagramm posten, das Sie in Bivariate erhalten, das Ihnen nicht gefällt, und ein anderes desselben Diagramms in Overlay Chart, das Ihnen gefällt? Es fällt mir schwer, mir den Unterschied im Verhalten vorzustellen, den Sie beschreiben.
In jmp gibt es immer einen Weg, das zu bekommen, was Sie wollen – wir helfen Ihnen gerne dabei, ihn zu finden.
@julianisch
