70374_it-IT

liliconcom

Scarica il database FDA 483 (Ispezioni del sito)

 

 

I dati delle citazioni sono forniti in "facile" per accedere ai fogli di calcolo che vengono estratti direttamente dagli strumenti di ispezione elettronica della FDA.  Ci warinings e caveat a parte la completezza dei dati: Ogni record non è incluso i registri manuali non sono inclusi e potrebbero essere solo risultati preliminari, non la forma finale, ecc.

 

I dati sono da questa pagina: https://www.fda.gov/ICECI/Inspections/ucm250720.htm

 

Tabella 1.  Dizionario dei dati

Centro Nome	Area del programma
Cita ID	Cite ID è un identificatore univoco per ogni citazione
Numero di riferimento CFR	Il codice delle norme federali di riferimento per la citazione
breve descrizione	Breve o descrizione del tipo di categoria
Descrizione lunga	La lunga descrizione è inserita nel modulo 483 della FDA
Frequenza	Il numero di volte durante l'anno fiscale in cui la citazione è stata utilizzata su un 483 per l'Area programma centrale
Anno	Termine derivato, per anno di tabella

 

 

 

names default to here(1);

dates = {"2006", "2007", "2008", "2009", "2010", "2011", "2012", "2013", "2014", "2015", "2016", "2017"}; 

pages = {"https://www.fda.gov/downloads/ICECI/Inspections/UCM255566.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM255565.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM255564.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM255563.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM255562.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM326092.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM326093.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM381532.xls", 
//note: file type changes and column headers change
"https://www.fda.gov/downloads/ICECI/Inspections/UCM423298.xlsx", "https://www.fda.gov/downloads/ICECI/Inspections/UCM481633.xlsx",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM531908.xlsx", "https://www.fda.gov/downloads/ICECI/Inspections/UCM589350.xlsx"};

For( i = 1, i <= N Items( pages ), i++,
 request = New HTTP Request( URL( pages[i] ), Method( "Get" ) );
//    file = request << Download( "/Users/bywing/Byron Wingerd/Examples/FDA 483 records/"||item(-1,pages[i],"/"), replace );
 file = request << Download(
  "/Users/bywing/Byron Wingerd/Examples/FDA 483 records/" || Char( dates[i] ) || "." || Item( -1, pages[i], "." ),
  replace
 );
 If( !Is Empty( file ), 
// note this puts a copy of the file in this directory 
  dt = Open(
   file,
   Worksheets(
    {"Biologics", "Bioresearch Monitoring", "Devices", "Drugs", "Foods", "Human Tissue", "Parts 1240 & 1250", "Rad Health",
    "Vet Med"}
   ),
   Use for all sheets( 1 ),
   Concatenate Worksheets( 1 ),
   Create Concatenation Column( 1 ),
   Worksheet Settings(
    1,
    Has Column Headers( 1 ),
    Number of Rows in Headers( 1 ),
    Headers Start on Row( 1 ),
    Data Starts on Row( 2 ),
    Data Starts on Column( 1 ),
    Data Ends on Row( 0 ),
    Data Ends on Column( 0 ),
    Replicated Spanned Rows( 1 ),
    Replicated Spanned Headers( 0 ),
    Suppress Hidden Rows( 1 ),
    Suppress Hidden Columns( 1 ),
    Suppress Empty Columns( 1 ),
    Treat as Hierarchy( 0 ),
    Multiple Series Stack( 0 ),
    Import Cell Colors( 0 ),
    Limit Column Detect( 0 ),
    Column Separator String( "-" )
   )
  )
 );
// cleaning and formatting the individual tables
 Try( :Ref No << set name( "Reference Number" ) );
 Try( :Short Desc << set name( "Short Description" ) );
 Try( :Long Desc << set name( "Long Description" ) );
 Try( :Frqncy << set name( "Frequency" ) );
 Try( dt << Clear Column Selection() );
 :Center Name << Set Selected( 1 );
 dt << Delete Columns();
 Try( :Source Table << set name( "Center Name" ) );
 dt << Select Where( :Reference Number == "" & :Short Description == "" & :Long Description == "" );
 dt << delete rows();
);//end for loop

Data Table( "2006" ) << Concatenate(
 Data Table( "2007" ),
 Data Table( "2008" ),
 Data Table( "2009" ),
 Data Table( "2010" ),
 Data Table( "2011" ),
 Data Table( "2012" ),
 Data Table( "2013" ),
 Data Table( "2014" ),
 Data Table( "2015" ),
 Data Table( "2016" ),
 Data Table( "2017" ),
 Output Table( "483's 2006 to 2017" ),
 Create source column
);

For( i = 1, i <= N Items( dates ), i++,
 dtr = Expr( Data Table() );
 Insert Into( dtr, dates[i] );
 Close( Eval( dtr ), no save );
 
);

 

 

https://community.jmp.com/t5/Byron-Wingerd-s-Blog/Fantastic-Trends-in-FDA-s-483s-and-How-to-Find-Them/ba-p/70362

Scienze di vita