70374_de-DE

liliconcom

Laden Sie die FDA 483-Datenbank (Site Inspections) herunter

 

 

Die Zitierdaten werden in "einfach" für den Zugriff auf Kalkulationstabellen bereitgestellt, die direkt aus den elektronischen Inspektionswerkzeugen der FDA abgerufen werden.  Es warinings und Vorbehalte über die Vollständigkeit der Daten: Jeder Datensatz ist nicht enthalten , manuelle Aufzeichnungen sind nicht enthalten, und dies können nur vorläufige Ergebnisse sein, nicht das endgültige Formular usw.

 

Die Daten stammen von dieser Seite: https://www.fda.gov/ICECI/Inspections/ucm250720.htm

 

Tabelle 1.  Datenwörterbuch

Name des Zentrums	Programmbereich
Zitieren Sie die ID	Die Zitierkennung ist eine eindeutige Kennung für jedes Zitat
CFR Referenznummer	Die Code of Federal Regulations Referenz für das Zitat
kurze Beschreibung	Kurz- oder Kategorietypbeschreibung
Lange Beschreibung	Die ausführliche Beschreibung ist auf dem FDA-Formular 483 eingetragen
Frequenz	Die Häufigkeit, mit der das Zitat während des Geschäftsjahres auf einer 483 für den Center-Programmbereich verwendet wurde
Jahr	Abgeleitete Laufzeit für das Jahr des Tisches

 

 

 

names default to here(1);

dates = {"2006", "2007", "2008", "2009", "2010", "2011", "2012", "2013", "2014", "2015", "2016", "2017"}; 

pages = {"https://www.fda.gov/downloads/ICECI/Inspections/UCM255566.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM255565.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM255564.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM255563.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM255562.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM326092.xls", "https://www.fda.gov/downloads/ICECI/Inspections/UCM326093.xls",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM381532.xls", 
//note: file type changes and column headers change
"https://www.fda.gov/downloads/ICECI/Inspections/UCM423298.xlsx", "https://www.fda.gov/downloads/ICECI/Inspections/UCM481633.xlsx",
"https://www.fda.gov/downloads/ICECI/Inspections/UCM531908.xlsx", "https://www.fda.gov/downloads/ICECI/Inspections/UCM589350.xlsx"};

For( i = 1, i <= N Items( pages ), i++,
 request = New HTTP Request( URL( pages[i] ), Method( "Get" ) );
//    file = request << Download( "/Users/bywing/Byron Wingerd/Examples/FDA 483 records/"||item(-1,pages[i],"/"), replace );
 file = request << Download(
  "/Users/bywing/Byron Wingerd/Examples/FDA 483 records/" || Char( dates[i] ) || "." || Item( -1, pages[i], "." ),
  replace
 );
 If( !Is Empty( file ), 
// note this puts a copy of the file in this directory 
  dt = Open(
   file,
   Worksheets(
    {"Biologics", "Bioresearch Monitoring", "Devices", "Drugs", "Foods", "Human Tissue", "Parts 1240 & 1250", "Rad Health",
    "Vet Med"}
   ),
   Use for all sheets( 1 ),
   Concatenate Worksheets( 1 ),
   Create Concatenation Column( 1 ),
   Worksheet Settings(
    1,
    Has Column Headers( 1 ),
    Number of Rows in Headers( 1 ),
    Headers Start on Row( 1 ),
    Data Starts on Row( 2 ),
    Data Starts on Column( 1 ),
    Data Ends on Row( 0 ),
    Data Ends on Column( 0 ),
    Replicated Spanned Rows( 1 ),
    Replicated Spanned Headers( 0 ),
    Suppress Hidden Rows( 1 ),
    Suppress Hidden Columns( 1 ),
    Suppress Empty Columns( 1 ),
    Treat as Hierarchy( 0 ),
    Multiple Series Stack( 0 ),
    Import Cell Colors( 0 ),
    Limit Column Detect( 0 ),
    Column Separator String( "-" )
   )
  )
 );
// cleaning and formatting the individual tables
 Try( :Ref No << set name( "Reference Number" ) );
 Try( :Short Desc << set name( "Short Description" ) );
 Try( :Long Desc << set name( "Long Description" ) );
 Try( :Frqncy << set name( "Frequency" ) );
 Try( dt << Clear Column Selection() );
 :Center Name << Set Selected( 1 );
 dt << Delete Columns();
 Try( :Source Table << set name( "Center Name" ) );
 dt << Select Where( :Reference Number == "" & :Short Description == "" & :Long Description == "" );
 dt << delete rows();
);//end for loop

Data Table( "2006" ) << Concatenate(
 Data Table( "2007" ),
 Data Table( "2008" ),
 Data Table( "2009" ),
 Data Table( "2010" ),
 Data Table( "2011" ),
 Data Table( "2012" ),
 Data Table( "2013" ),
 Data Table( "2014" ),
 Data Table( "2015" ),
 Data Table( "2016" ),
 Data Table( "2017" ),
 Output Table( "483's 2006 to 2017" ),
 Create source column
);

For( i = 1, i <= N Items( dates ), i++,
 dtr = Expr( Data Table() );
 Insert Into( dtr, dates[i] );
 Close( Eval( dtr ), no save );
 
);

 

 

https://community.jmp.com/t5/Byron-Wingerd-s-Blog/Fantastic-Trends-in-FDA-s-483s-and-How-to-Find-Them/ba-p/70362

Biowissenschaften