84699_zh-CN

liliconcom

是否可以计算矩阵中的分布和置信区间

所有，
我期待计算一些数据的置信区间。我知道可以使用以下方法实现此目的： 

 

// Gets me what I want 
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Obj = dt << Distribution( Column( :Age, :Weight ) );
Obj << Confidence Interval(0.95);

// How to achieve using matrix
Mat = dt << Get As Matrix; 
Obj = Distribution(Mat[0,1]) << Confidence Interval(0.95);

     如果我想通过小组进一步做到这一点，上面变得特别困难，让我们假设我是否必须按年龄分组？任何指导表示赞赏 

Re：是否可以计算矩阵中的分布和置信区间

我不会做矩阵操作，我会做这样的事情，

 

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Obj = dt << Distribution( Column( :height, :weight ), by(:sex), "Invisible" );
Obj << Confidence Interval(0.95);
Report(Obj[1])["Confidence Intervals"][TableBox(1)] << make combined data table;
Obj << close window;

您可以执行矩阵函数，但需要按组（年龄或性别）查找所有唯一，然后索引矩阵。  存在可能感兴趣的矩阵CDF功能。  下面的脚本是一个FYI，不推荐，但这里是公式。生成的矩阵没有by组或哪个变量。我推荐上面的方法。

 

Mat = dt << Get As Matrix; 
//Obj = Distribution(Mat[0,1]) << Confidence Interval(0.95);



/* CDF function */
/* only one column at a time get weight*/
{Quant, CumProb} = CDF( Mat[0,3] ); 

mxb = V Mean(Mat);
msd = V Std(Mat);
mdf = V Sum( !IsMissing(Mat) ) -1;

xb_lci = mxb - msd:/sqrt(mdf+1) :* tquantile(0.975,mdf);
xb_uci = mxb + msd:/sqrt(mdf+1) :* tquantile(0.975,mdf);

sd_lci =  msd :* sqrt( mdf :/ ChiSquareQuantile(0.975,mdf)); 
sd_uci =  msd :* sqrt( mdf :/ ChiSquareQuantile(0.025, mdf));

show(Quant, CumProb, mxb[3], msd[3], xb_lci[3], xb_uci[3], sd_lci[3], sd_uci[3]);